-
Notifications
You must be signed in to change notification settings - Fork 1
Expand file tree
/
Copy pathgraphM.asm
More file actions
864 lines (789 loc) · 29.4 KB
/
graphM.asm
File metadata and controls
864 lines (789 loc) · 29.4 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
; Dust Ultimate Game Library (DUGL)
; Copyright (C) 2025 Fakhri Feki
;
; This program is free software: you can redistribute it and/or modify
; it under the terms of the GNU General Public License as published by
; the Free Software Foundation, either version 3 of the License, or
; (at your option) any later version.
; This program is distributed in the hope that it will be useful,
; but WITHOUT ANY WARRANTY; without even the implied warranty of
; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
; GNU General Public License for more details.
; You should have received a copy of the GNU General Public License
; along with this program. If not, see <https://www.gnu.org/licenses/>.
;
; contact: libdugl(at)hotmail.com
;=============================================================================
%include "PARAM.asm"
%include "DGUTILS.asm"
; enable windows/linux win32/elf32 building
%pragma elf32 gprefix
%pragma win32 gprefix _
; GLOBAL Functions
GLOBAL GetMaxResVSetSurf, BlndCol16
GLOBAL DgSurfCGetPixel16, DgSurfCPutPixel16
GLOBAL SurfCopy, SurfMaskCopy16, SurfCopyBlnd16, SurfCopyTrans16
; GLOBAL Internal functions
GLOBAL InHLineUVCompute, ClipHLineXCompute
; GLOBAL Vars
GLOBAL QBlue16Mask, QGreen16Mask, QRed16Mask, WBGR16Mask
GLOBAL PntInitCPTDbrd, DGDQ0_1_2_3, NegDecPosInc, MaxPolyDeltaDim, DGDQInitCPTDbrd
GLOBAL MaskB_RGB16, MaskG_RGB16, MaskR_RGB16, RGB16_PntNeg, Mask2B_RGB16, Mask2G_RGB16, Mask2R_RGB16
GLOBAL RGBDebMask_GGG, RGBDebMask_IGG, RGBDebMask_GIG, RGBDebMask_IIG, RGBDebMask_GGI, RGBDebMask_IGI, RGBDebMask_GII, RGBDebMask_III
GLOBAL RGBFinMask_GGG, RGBFinMask_IGG, RGBFinMask_GIG, RGBFinMask_IIG, RGBFinMask_GGI, RGBFinMask_IGI, RGBFinMask_GII, RGBFinMask_III
GLOBAL DgNanoSurf, dummyDBMFONT, RendFrontSurf, RendSurf
BITS 32
SECTION .text ALIGN=32
%include "fasthzline16.asm"
%include "hzline16.asm"
BlndCol16:
ARG SrcCol16, 4, DstCol16, 4, BlndVal16, 4
MOV ECX,[EBP+BlndVal16] ;
MOV EAX,[EBP+SrcCol16] ;
AND ECX,BYTE BlendMask
MOV EDX,[EBP+DstCol16] ;
JZ .FinBlndCol16
CMP CL,31
JZ .ChooseDst16
MOVD xmm3,ECX ; dst Mul
MOVD xmm0,EAX ; srcCol16 | 0 | 0 | 0
MOVD xmm1,EDX ; dstCol16 | 0 | 0 | 0
XOR CL,BlendMask ; = 31-blendVal
PSHUFD xmm3,xmm3, (0<<6) | (0<<4) | (0<<2) | (0) ; dst Mul | dst Mul | dst Mul | dst Mul
PSHUFLW xmm0,xmm0,(0<<6) | (0<<4) | (0<<2) | (0) ; srcCol16 | srcCol16 | srcCol16 | srcCol16
PSHUFLW xmm1,xmm1,(0<<6) | (0<<4) | (0<<2) | (0) ; dstCol16 | dstCol16 | dstCol16 | dstCol16
MOVD xmm2,ECX ; src Mul
PAND xmm0, [WBGR16Mask] ; srcColB16 | srcColG16 | srcColR16 | srcColR16
PSHUFD xmm2,xmm2, (0<<6) | (0<<4) | (0<<2) | (0) ; src Mul | src Mul | src Mul | src Mul
PAND xmm1, [WBGR16Mask] ; dstColB16 | dstColG16 | dstColR16 | dstColR16
PMOVZXWD xmm0, xmm0 ; extend 16 bits Word src color de 32 bit DWord
PMOVZXWD xmm1, xmm1 ; extend 16 bits Word dst color de 32 bit DWord
PMULLD xmm0, xmm2 ; *= srcMul
PMULLD xmm1, xmm3 ; *= dstMul
PADDD xmm0, xmm1 ; xmm0 = srcCol (R|G|B|B) * srcMul + dstCol (R|G|B|B) * dstMul
PSRLD xmm0, 5
PSHUFD xmm4,xmm0, (1<<6) | (1<<4) | (1<<2) | (1)
PSHUFD xmm5,xmm0, (2<<6) | (2<<4) | (2<<2) | (2)
;PAND xmm0,[QBlue16Mask]
PAND xmm4,[QGreen16Mask]
PAND xmm5,[QRed16Mask]
POR xmm0,xmm4
POR xmm0,xmm5
MOVD EAX,xmm0
JMP .FinBlndCol16
.ChooseDst16:
MOV EAX,EDX
.FinBlndCol16:
RETURN
GetMaxResVSetSurf:
MOV EAX,MaxResV
RET
ALIGN 32
SurfCopy:
ARG PDstSrf, 4, PSrcSrf, 4
PUSH EDI
PUSH ESI
PUSH EBX
MOV ESI,[EBP+PSrcSrf]
MOV EDI,[EBP+PDstSrf]
MOV EBX,[ESI+DuglSurf.SizeSurf]
MOV EDI,[EDI+DuglSurf.rlfb]
MOV ESI,[ESI+DuglSurf.rlfb]
XOR ECX,ECX
TEST EDI,0x7
JZ .CpyMMX
.CopyBAv:
TEST EDI,0x1
JZ .PasCopyBAv
OR EBX,EBX
JZ .FinSurfCopy
DEC EBX
MOVSB
.PasCopyBAv:
.CopyWAv:
TEST EDI,0x2
JZ .PasCopyWAv
CMP EBX,BYTE 2
JL .CopyBAp
SUB EBX,BYTE 2
MOVSW
.PasCopyWAv:
.CopyDAv:
TEST EDI,0x4
JZ .PasCopyDAv
CMP EBX,BYTE 4
JL .CopyWAp
SUB EBX,BYTE 4
MOVSD
.PasCopyDAv:
TEST EDI,0x8
JZ .PasCopyQAv
CMP EBX,BYTE 8
JL .CopyWAp
MOVQ xmm0,[ESI]
SUB EBX,8
MOVQ [EDI],xmm0
LEA ESI,[ESI+8]
LEA EDI,[EDI+8]
.PasCopyQAv:
.CpyMMX:
SHLD ECX,EBX,26 ; ECX = EBX >> 6 ; ECX should be zero
JZ SHORT .PasCpyMMXBloc
AND EBX,BYTE 0x3F
.BcCpyMMXBloc:
MOVDQU xmm0,[ESI]
MOVDQU xmm1,[ESI+32]
MOVDQU xmm2,[ESI+16]
MOVDQU xmm3,[ESI+48]
MOVDQA [EDI],xmm0
MOVDQA [EDI+32],xmm1
MOVDQA [EDI+16],xmm2
MOVDQA [EDI+48],xmm3
DEC ECX
LEA ESI,[ESI+64]
LEA EDI,[EDI+64]
JNZ SHORT .BcCpyMMXBloc
.PasCpyMMXBloc:
SHLD ECX,EBX,29 ; ECX = EBX >> 3 ; ECX should be zero
JZ SHORT .PasCpyMMX
AND EBX,BYTE 7
.BcCpyMMX:
MOVQ xmm0,[ESI]
DEC ECX
MOVQ [EDI],xmm0
LEA ESI,[ESI+8]
LEA EDI,[EDI+8]
JNZ SHORT .BcCpyMMX
.PasCpyMMX:
.CopyDAp:
CMP EBX,BYTE 4
JL .CopyWAp
SUB EBX,BYTE 4
MOVSD
.PasCopyDAp:
.CopyWAp:
CMP EBX,BYTE 2
JL .CopyBAp
SUB EBX,BYTE 2
MOVSW
.PasCopyWAp:
.CopyBAp:
OR EBX,EBX
JZ .FinSurfCopy
MOVSB
.PasCopyBAp:
.FinSurfCopy:
POP EBX
POP ESI
POP EDI
RETURN
ALIGN 32
SurfMaskCopy16:
ARG PDstSrfMaskB, 4, PSrcSrfMaskB, 4
PUSH ESI
PUSH EDI
PUSH EBX
MOV ESI,[EBP+PSrcSrfMaskB]
MOV EDI,[EBP+PDstSrfMaskB]
MOV EBX,[ESI+DuglSurf.SizeSurf]
PSHUFLW xmm3,[ESI+DuglSurf.Mask],0
MOV EDI,[EDI+DuglSurf.rlfb]
PUNPCKLQDQ xmm3,xmm3
SHR EBX,1
MOV ESI,[ESI+DuglSurf.rlfb]
MOVD EBP,xmm3
XOR ECX,ECX
.BcStBAv:
TEST EDI,6 ; dword aligned ?
JZ .FPasStBAv
MOV AX,[ESI]
CMP AX,BP
LEA ESI,[ESI+2]
JZ .PasStBAv
STOSW
DEC EBX
JZ .FinSHLine
JMP .BcStBAv
.PasStBAv:
DEC EBX
LEA EDI,[EDI+2]
JZ .FinSHLine
JMP .BcStBAv
.FPasStBAv:
;--------
TEST EDI, 8
JZ .PasStQAv
CMP EBX,BYTE 4
JL .StBAp
MOVQ xmm2,[ESI]
MOVQ xmm1,xmm2
MOVQ xmm0,xmm2
MOVQ xmm4,[EDI]
PCMPEQW xmm2,xmm3 ; [DQ16Mask]
PCMPEQW xmm1,xmm3 ; [DQ16Mask]
PANDN xmm2,xmm0
PAND xmm4,xmm1
POR xmm2,xmm4
SUB EBX, BYTE 4
MOVQ [EDI],xmm2
LEA ESI,[ESI+8]
LEA EDI,[EDI+8]
.PasStQAv:
;-------
SHLD ECX,EBX,29
JZ .StBAp
;ALIGN 4
.StoSSE:
MOVDQU xmm2,[ESI]
MOVDQA xmm4,[EDI]
MOVDQA xmm1,xmm2
MOVDQA xmm0,xmm2
PCMPEQW xmm1,xmm3 ; [DQ16Mask]
PCMPEQW xmm2,xmm3 ; [DQ16Mask]
PAND xmm4,xmm1
PANDN xmm2,xmm0
POR xmm2,xmm4
DEC ECX
MOVDQA [EDI],xmm2
LEA ESI,[ESI+16]
LEA EDI,[EDI+16]
JNZ .StoSSE
.StBAp:
AND BL,BYTE 7
JZ .FinSHLine
.StQAp:
TEST BL,4
JZ .PasStQAp
MOVQ xmm2,[ESI]
MOVQ xmm1,xmm2
MOVQ xmm0,xmm2
MOVQ xmm4,[EDI]
PCMPEQW xmm2,xmm3 ; [DQ16Mask]
PCMPEQW xmm1,xmm3 ; [DQ16Mask]
PANDN xmm2,xmm0
PAND xmm4,xmm1
POR xmm2,xmm4
MOVQ [EDI],xmm2
LEA ESI,[ESI+8]
LEA EDI,[EDI+8]
.PasStQAp:
AND BL,BYTE 3
JZ SHORT .FinSHLine
.BcStBAp:
MOV AX,[ESI]
CMP AX,BP
LEA ESI,[ESI+2]
JZ .BPasStBAp
DEC BL
STOSW
JNZ .BcStBAp
JMP SHORT .FinSHLine
.BPasStBAp:
DEC BL
LEA EDI,[EDI+2]
JNZ .BcStBAp
.PasStBAp:
.FinSHLine:
POP EBX
POP EDI
POP ESI
RETURN
ALIGN 32
SurfCopyBlnd16:
ARG PDstSrfB, 4, PSrcSrfB, 4, SCBCol, 4
PUSH EDI
PUSH ESI
PUSH EBX
; prepare col blending
MOV EAX,[EBP+SCBCol] ;
MOV EBX,EAX ;
MOV ECX,EAX ;
MOV EDX,EAX ;
AND EBX,[QBlue16Mask] ; EBX = Bclr16 | Bclr16
SHR EAX,24
AND ECX,[QGreen16Mask] ; ECX = Gclr16 | Gclr16
AND AL,BlendMask ; remove any ineeded bits
AND EDX,[QRed16Mask] ; EDX = Rclr16 | Rclr16
XOR AL,BlendMask ; 31-blendsrc
MOV EDI,EAX
XOR AL,BlendMask ; 31-blendsrc
INC AL
SHR DX,5 ; right shift red 5bits
IMUL BX,AX
IMUL CX,AX
IMUL DX,AX
MOVD xmm3,EBX
MOVD xmm4,ECX
MOVD xmm5,EDX
MOVD xmm7,EDI
PSHUFLW xmm3,xmm3,0
PSHUFLW xmm4,xmm4,0
PSHUFLW xmm5,xmm5,0
PSHUFLW xmm7,xmm7,0
PUNPCKLQDQ xmm3,xmm3
PUNPCKLQDQ xmm4,xmm4
PUNPCKLQDQ xmm5,xmm5
PUNPCKLQDQ xmm7,xmm7
MOV ESI,[EBP+PSrcSrfB]
MOV EDI,[EBP+PDstSrfB]
MOV EBX,[ESI+DuglSurf.SizeSurf]
MOV EDI,[EDI+DuglSurf.rlfb]
SHR EBX,1
MOV ESI,[ESI+DuglSurf.rlfb]
XOR ECX,ECX
.BcStBAv:
TEST EDI,6 ; dword aligned ?
JZ .FPasStBAv
MOV AX,[ESI]
DEC EBX
MOVD xmm0,EAX
MOVD xmm1,EAX
MOVD xmm2,EAX
@SolidBlndQ
MOVD EAX,xmm0
LEA ESI,[ESI+2]
STOSW
JZ .FinSHLine
JMP SHORT .BcStBAv
.FPasStBAv:
TEST EDI, 8
JZ .PasStQAv
CMP EBX,BYTE 4
JL .StBAp
MOVQ xmm0,[ESI]
MOVQ xmm1,xmm0
MOVQ xmm2,xmm0
@SolidBlndQ
SUB EBX, BYTE 4
MOVQ [EDI],xmm0
LEA ESI,[ESI+8]
LEA EDI,[EDI+8]
.PasStQAv:
SHLD ECX,EBX,29 ; ECX = (EBX >> 2) : ECX should be zero
JZ .StBAp
;ALIGN 4
.StoSSE:
MOVDQU xmm0,[ESI]
MOVDQA xmm1,xmm0
MOVDQA xmm2,xmm0
@SolidBlndQ
DEC ECX
MOVDQA [EDI],xmm0
LEA ESI,[ESI+16]
LEA EDI,[EDI+16]
JNZ .StoSSE
.StBAp:
AND BL,BYTE 7
JZ .FinSHLine
.StQAp:
TEST BL,4
JZ .PasStQAp
MOVQ xmm0,[ESI]
MOVQ xmm1,xmm0
MOVQ xmm2,xmm0
@SolidBlndQ
MOVQ [EDI],xmm0
LEA ESI,[ESI+8]
LEA EDI,[EDI+8]
.PasStQAp:
AND BL,BYTE 3
JZ SHORT .FinSHLine
.BcStBAp:
MOV AX,[ESI]
DEC BL
MOVD xmm0,EAX
MOVD xmm1,EAX
MOVD xmm2,EAX
@SolidBlndQ
MOVD EAX,xmm0
LEA ESI,[ESI+2]
STOSW
JNZ .BcStBAp
.PasStBAp:
.FinSHLine:
POP EBX
POP ESI
POP EDI
RETURN
ALIGN 32
SurfCopyTrans16:
ARG PDstSrfT, 4, PSrcSrfT, 4, SCTrans, 4
PUSH EDI
PUSH ESI
PUSH EBX
; prepare col blending
MOV EAX,[EBP+SCTrans] ;
AND EAX,BYTE BlendMask
JZ .FinSHLine
MOV EDX,EAX ;
INC EAX
XOR DL,BlendMask ; 31-blendsrc
MOVD xmm7,EAX
MOVD xmm6,EDX
PSHUFLW xmm7,xmm7,0
PSHUFLW xmm6,xmm6,0
PUNPCKLQDQ xmm7,xmm7
PUNPCKLQDQ xmm6,xmm6
MOV ESI,[EBP+PSrcSrfT]
MOV EDI,[EBP+PDstSrfT]
MOV EBX,[ESI+DuglSurf.SizeSurf]
MOV EDI,[EDI+DuglSurf.rlfb]
SHR EBX,1
MOV ESI,[ESI+DuglSurf.rlfb]
XOR ECX,ECX
.BcStBAv:
TEST EDI,6 ; dword aligned ?
JZ .FPasStBAv
MOV AX,[ESI]
MOVD xmm0,EAX
DEC EBX
MOV AX,[EDI]
MOVQ xmm1,xmm0
MOVD xmm3,EAX
MOVQ xmm2,xmm0
MOVQ xmm4,xmm3
MOVQ xmm5,xmm3
@TransBlndQ
LEA ESI,[ESI+2]
PEXTRW [EDI],xmm0,0
LEA EDI,[EDI+2]
JZ .FinSHLine
JMP .BcStBAv
.FPasStBAv:
;--------
TEST EDI, 8
JZ .PasStQAv
CMP EBX,BYTE 4
JL .StBAp
MOVQ xmm0,[ESI]
MOVQ xmm3,[EDI]
MOVQ xmm1,xmm0
MOVQ xmm4,xmm3
MOVQ xmm2,xmm0
MOVQ xmm5,xmm3
@TransBlndQ
SUB EBX, BYTE 4
MOVQ [EDI],xmm0
LEA ESI,[ESI+8]
LEA EDI,[EDI+8]
.PasStQAv:
;-------
SHLD ECX,EBX,29
JZ .StBAp
;ALIGN 4
.StoSSE:
MOVDQU xmm0,[ESI]
MOVDQA xmm3,[EDI]
MOVDQA xmm1,xmm0
MOVDQA xmm4,xmm3
MOVDQA xmm2,xmm0
MOVDQA xmm5,xmm3
@TransBlndQ
DEC ECX
MOVDQA [EDI],xmm0
LEA ESI,[ESI+16]
LEA EDI,[EDI+16]
JNZ .StoSSE
.StBAp:
AND BL,BYTE 7
JZ .FinSHLine
.StQAp:
TEST BL,4
JZ .PasStQAp
MOVQ xmm0,[ESI]
MOVQ xmm3,[EDI]
MOVQ xmm1,xmm0
MOVQ xmm4,xmm3
MOVQ xmm2,xmm0
MOVQ xmm5,xmm3
@TransBlndQ
MOVQ [EDI],xmm0
LEA ESI,[ESI+8]
LEA EDI,[EDI+8]
.PasStQAp:
AND BL,BYTE 3
JZ .FinSHLine
.BcStBAp:
MOV AX,[ESI]
MOVD xmm0,EAX
DEC BL
MOV AX,[EDI]
MOVQ xmm1,xmm0
MOVD xmm3,EAX
MOVQ xmm2,xmm0
MOVQ xmm4,xmm3
MOVQ xmm5,xmm3
@TransBlndQ
LEA ESI,[ESI+2]
PEXTRW [EDI],xmm0,0
LEA EDI,[EDI+2]
JNZ .BcStBAp
.PasStBAp:
.FinSHLine:
POP EBX
POP ESI
POP EDI
RETURN
DgSurfCGetPixel16:
ARG PSURFCGP, 4, SCGPPX, 4, SCGPPY, 4
MOV EDX,[EBP+SCGPPY]
MOV ECX,[EBP+SCGPPX]
MOV EAX,0xFFFFFFFF
MOV EBP,[EBP+PSURFCGP]
CMP EDX,[EBP+DuglSurf.MaxY]
JG SHORT .Clip
CMP ECX,[EBP+DuglSurf.MaxX]
JG SHORT .Clip
CMP EDX,[EBP+DuglSurf.MinY]
JL SHORT .Clip
CMP ECX,[EBP+DuglSurf.MinX]
JL SHORT .Clip
IMUL EDX,[EBP+DuglSurf.NegScanLine]
ADD EDX,[EBP+DuglSurf.vlfb]
MOVZX EAX,WORD [EDX+ECX*2]
.Clip:
RETURN
DgSurfCPutPixel16:
ARG PSURFCPP, 4, SCPPPX, 4, SCPPPY, 4, SCPPCOL, 4
MOV EAX,[EBP+PSURFCGP]
MOV EDX,[EBP+SCPPPY]
MOV ECX,[EBP+SCPPPX]
CMP EDX,[EAX+DuglSurf.MaxY]
JG SHORT .Clip
CMP ECX,[EAX+DuglSurf.MaxX]
JG SHORT .Clip
CMP EDX,[EAX+DuglSurf.MinY]
JL SHORT .Clip
CMP ECX,[EAX+DuglSurf.MinX]
JL SHORT .Clip
IMUL EDX,[EAX+DuglSurf.NegScanLine]
MOV BP,[EBP+SCPPCOL]
ADD EDX,[EAX+DuglSurf.vlfb]
MOV [EDX+ECX*2],BP
.Clip:
RETURN
; U,V Hlines computing internal function
; INPUT: (EAX, EDI)=(U1,U2), (ECX,EBP)=(YP1,YP2), EBX: start Dest addr
InHLineUVCompute:
JE .DUZero
JL SHORT .U2Greater
; U1 Greater
SUB ECX,EBP ; [YP1]-[YP2]
SHL EAX,Prec
CDQ
IDIV ECX
MOVD xmm3,EAX
MOVD xmm4,EAX
MOVD xmm5,EDI
PSHUFD xmm3,xmm3,0 ; = PntU | PntU | PntU | PntU
PSHUFD xmm4,xmm4,0 ; = PntU | PntU | PntU | PntU
PSHUFD xmm5,xmm5,0 ; = U2 | U2 | U2 | U2
PMULLD xmm3,xmm7 ; * (0|1|2|3) = 0 | PntU | PntU*2 | PntU*3
.HUCommon:
PSLLD xmm4,2 ; ; = PntU*4 | PntU*4 | PntU*4 | PntU*4
MOVDQA xmm0,xmm3
PSRAD xmm0,Prec ; Prec = DU | DU | DU | DU
.LpHLine:
CMP ECX,BYTE 2
PADDD xmm0,xmm5 ;
JLE SHORT .LastBytes
PADDD xmm3,xmm4 ; Progress PntU
MOVDQU [EBX],xmm0
SUB ECX,BYTE 4
LEA EBX,[EBX+16]
JS SHORT .endHLine
MOVDQA xmm0,xmm3
PSRAD xmm0,Prec
JMP SHORT .LpHLine
; U2 Greater
.U2Greater:
SHL EAX,Prec
SUB ECX,EBP ; [YP1]-[YP2]
CDQ
IDIV ECX
MOVD xmm3,EAX
MOVD xmm4,EAX
MOVD xmm5,EDI
PSHUFD xmm3,xmm3,0 ; = PntU | PntU | PntU | PntU
PSHUFD xmm4,xmm4,0 ; = PntU | PntU | PntU | PntU
PMULLD xmm3,xmm7 ; * (0|1|2|3) = 0 | PntU | PntU*2 | PntU*3
PSHUFD xmm5,xmm5,0 ; = U2 | U2 | U2 | U2
PADDD xmm3,[DGDQInitCPTDbrd] ; += ((1<<Prec)-1) | += ((1<<Prec)-1) | += ((1<<Prec)-1) | += ((1<<Prec)-1)
JMP SHORT .HUCommon
; Delta U zero
.DUZero:
SUB ECX,EBP ; [YP1] - [YP2]
MOVD xmm0,EDI ; = U2
PSHUFD xmm0,xmm0,0 ; = U2 | U2 | U2 | U2
.LpDUZ:
CMP ECX,BYTE 2
JLE SHORT .LastBytes
MOVDQU [EBX],xmm0
SUB ECX,BYTE 4
LEA EBX,[EBX+16]
JS SHORT .endHLine
JMP SHORT .LpDUZ
.LastBytes:
JE SHORT .Last3Bytes
CMP ECX,BYTE 1
JE SHORT .Last2Bytes
.Last1Byte:
MOVD [EBX],xmm0
JMP SHORT .endHLine
.Last2Bytes:
MOVQ [EBX],xmm0
JMP SHORT .endHLine
.Last3Bytes:
MOVQ [EBX],xmm0
PEXTRD [EBX+8],xmm0,2
.endHLine:
RET
; X/U/V clip contour computing internal function
; INPUT: EAX=PntX/PntU/PntV, EDI=X2/U2/V2, ECX=DY (steps count), EBX: start Dest addr, mm1: steps to jump
ClipHLineXCompute:
JE .DXZero
JL SHORT .X2Greater
; X1/U1/V1 Greater
MOVQ2DQ xmm0,mm1
MOVD xmm3,EAX
MOVD xmm4,EAX
MOVD xmm5,EDI
PSHUFD xmm0,xmm0,0 ; = Steps | Steps | Steps | Steps
PSHUFD xmm3,xmm3,0 ; = PntX | PntX | PntX | PntX
PSHUFD xmm4,xmm4,0 ; = PntX | PntX | PntX | PntX
PMULLD xmm0,xmm3 ; = Steps * PntX | Steps * PntX | Steps * PntX | Steps * PntX
PSHUFD xmm5,xmm5,0 ; = X2 | X2 | X2 | X2
PMULLD xmm3,xmm7 ; * (0|1|2|3) = 0 | PntX | PntX*2 | PntX*3
.HXCommon:
PADDD xmm3,xmm0 ; += Steps * PntX | += Steps * PntX | += Steps * PntX | += Steps * PntX
PSLLD xmm4,2 ; ; = PntX*4 | PntX*4 | PntX*4 | PntX*4
MOVDQA xmm0,xmm3
PSRAD xmm0,Prec ; Prec = DU | DU | DU | DU
.LpHLine:
CMP ECX,BYTE 2
PADDD xmm0,xmm5 ;
JLE SHORT .LastBytes
PADDD xmm3,xmm4 ; Progress PntX
MOVDQU [EBX],xmm0
SUB ECX,BYTE 4
LEA EBX,[EBX+16]
JS SHORT .endHLine
MOVDQA xmm0,xmm3
PSRAD xmm0,Prec
JMP SHORT .LpHLine
; X2 Greater
.X2Greater:
MOVQ2DQ xmm0,mm1
MOVD xmm3,EAX
MOVD xmm4,EAX
MOVD xmm5,EDI
PSHUFD xmm0,xmm0,0 ; = Steps | Steps | Steps | Steps
PSHUFD xmm3,xmm3,0 ; = PntX | PntX | PntX | PntX
PSHUFD xmm4,xmm4,0 ; = PntX | PntX | PntX | PntX
PMULLD xmm0,xmm3 ; = Steps * PntX | Steps * PntX | Steps * PntX | Steps * PntX
PSHUFD xmm5,xmm5,0 ; = X2 | X2 | X2 | X2
PMULLD xmm3,xmm7 ; * (0|1|2|3) = 0 | PntX | PntX*2 | PntX*3
PADDD xmm3,[DGDQInitCPTDbrd] ; += ((1<<Prec)-1) | += ((1<<Prec)-1) | += ((1<<Prec)-1) | += ((1<<Prec)-1)
JMP SHORT .HXCommon
; Delta X zero
.DXZero:
MOVD xmm0,EDI ; = X2
PSHUFD xmm0,xmm0,0 ; = X2 | X2 | X2 | X2
.LpDXZ:
CMP ECX,BYTE 2
JLE SHORT .LastBytes
MOVDQU [EBX],xmm0
SUB ECX,BYTE 4
LEA EBX,[EBX+16]
JS SHORT .endHLine
JMP SHORT .LpDXZ
.LastBytes:
JE SHORT .Last3Bytes
CMP ECX,BYTE 1
JE SHORT .Last2Bytes
.Last1Byte:
MOVD [EBX],xmm0
JMP SHORT .endHLine
.Last2Bytes:
MOVQ [EBX],xmm0
JMP SHORT .endHLine
.Last3Bytes:
MOVQ [EBX],xmm0
PEXTRD [EBX+8],xmm0,2
.endHLine:
RET
SECTION .data ALIGN=32
DgNanoSurf:
NScanLine DD 2
Nrlfb DD NOffVMem
NOrgX DD 0
NOrgY DD 0
NMaxX DD 0
NMaxY DD 0
NMinX DD 0
NMinY DD 0;-----------------------
NMask DD 0
NResH DD 1
NResV DD 1
Nvlfb DD NOffVMem
NNegScanLine DD -2
NOffVMem DD 0
NBitsPixel DD 16
NSizeSurf DD 2;-----------------------
dummyDBMFONT:
BMCharsSSurfs DD 256 dup (DgNanoSurf)
BMCharsPlusX DD 256 dup (0)
BMCharsWidth DD 256 dup (1)
BMCharsHeight DD 256 dup (1)
BMCharsXOffset DD 256 dup (0)
BMCharsYOffset DD 256 dup (0)
BMCharsGHeight DD 1
BMCharsGLineHeight DD 1
BMCharX DD 0
BMCharY DD 0
BMCharCurChar DD 0
BMCharsMainSurf DD 0
BMCharsRendX DD 0
BMCharsRendY DD 0;--------------
; BLENDING 16BPP ----------
QBlue16Mask DW CMaskB_RGB16,CMaskB_RGB16,CMaskB_RGB16,CMaskB_RGB16
Q2Blue16Mask DW CMaskB_RGB16,CMaskB_RGB16,CMaskB_RGB16,CMaskB_RGB16
QGreen16Mask DW CMaskG_RGB16,CMaskG_RGB16,CMaskG_RGB16,CMaskG_RGB16
Q2Green16Mask DW CMaskG_RGB16,CMaskG_RGB16,CMaskG_RGB16,CMaskG_RGB16
QRed16Mask DW CMaskR_RGB16,CMaskR_RGB16,CMaskR_RGB16,CMaskR_RGB16
Q2Red16Mask DW CMaskR_RGB16,CMaskR_RGB16,CMaskR_RGB16,CMaskR_RGB16
WBGR16Mask DW CMaskB_RGB16,CMaskG_RGB16,CMaskR_RGB16,CMaskR_RGB16
W2BGR16Mask DW CMaskB_RGB16,CMaskG_RGB16,CMaskR_RGB16,CMaskR_RGB16
MaxPolyDeltaDim DD MaxDeltaDim, MaxDeltaDim, 0, 0
PntInitCPTDbrd DD 0,((1<<Prec)-1)
MaskB_RGB16 DD 0x1f ; blue bits 0->4
MaskG_RGB16 DD 0x3f<<5 ; green bits 5->10
MaskR_RGB16 DD 0x1f<<11 ; red bits 11->15
RGB16_PntNeg DD ((1<<Prec)-1) ;----------
Mask2B_RGB16 DD 0x1f,0x1f ; blue bits 0->4
Mask2G_RGB16 DD 0x3f<<5,0x3f<<5 ; green bits 5->10 ;----------
Mask2R_RGB16 DD 0x1f<<11,0x1f<<11 ; red bits 11->15
RGBDebMask_GGG DD 0,0,0,0
RGBDebMask_IGG DD ((1<<Prec)-1),0,0,0
RGBDebMask_GIG DD 0,((1<<(Prec+5))-1),0,0
RGBDebMask_IIG DD ((1<<Prec)-1),((1<<(Prec+5))-1),0,0
RGBDebMask_GGI DD 0,0,((1<<(Prec+11))-1),0
RGBDebMask_IGI DD ((1<<Prec)-1),0,((1<<(Prec+11))-1),0
RGBDebMask_GII DD 0,((1<<(Prec+5))-1),((1<<(Prec+11))-1),0
RGBDebMask_III DD ((1<<Prec)-1),((1<<(Prec+5))-1),((1<<(Prec+11))-1),0
RGBFinMask_GGG DD ((1<<Prec)-1),((1<<(Prec+5))-1),((1<<(Prec+11))-1),0
RGBFinMask_IGG DD 0,((1<<(Prec+5))-1),((1<<(Prec+11))-1),0
RGBFinMask_GIG DD ((1<<Prec)-1),0,((1<<(Prec+11))-1),0
RGBFinMask_IIG DD 0,0,((1<<(Prec+11))-1),0
RGBFinMask_GGI DD ((1<<Prec)-1),((1<<(Prec+5))-1),0,0
RGBFinMask_IGI DD 0,((1<<(Prec+5))-1),0,0
RGBFinMask_GII DD ((1<<Prec)-1),0,0,0
RGBFinMask_III DD 0,0,0,0
DGDQ0_1_2_3 DD 0, 1, 2, 3
DGDQInitCPTDbrd DD ((1<<Prec)-1),((1<<Prec)-1),((1<<Prec)-1),((1<<Prec)-1)
NegDecPosInc DD -1, 1, 0, 0
; the main Surf 16bpp that DUGL will render to
; user mostly has to set this as CurSurf unless other intermediate DgSurf
RendSurf DD 0
RendFrontSurf DD 0
SECTION .bss ALIGN=32