-
Notifications
You must be signed in to change notification settings - Fork 1
Expand file tree
/
Copy pathimage.asm
More file actions
393 lines (347 loc) · 10.3 KB
/
image.asm
File metadata and controls
393 lines (347 loc) · 10.3 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
; Dust Ultimate Game Library (DUGL)
; Copyright (C) 2025 Fakhri Feki
;
; This program is free software: you can redistribute it and/or modify
; it under the terms of the GNU General Public License as published by
; the Free Software Foundation, either version 3 of the License, or
; (at your option) any later version.
; This program is distributed in the hope that it will be useful,
; but WITHOUT ANY WARRANTY; without even the implied warranty of
; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
; GNU General Public License for more details.
; You should have received a copy of the GNU General Public License
; along with this program. If not, see <https://www.gnu.org/licenses/>.
;
; contact: libdugl(at)hotmail.com
;=============================================================================
%include "PARAM.asm"
; enable windows/linux win32/elf32 building
%pragma elf32 gprefix
%pragma win32 gprefix _
; GLOBAL Function*************************************************************
GLOBAL InRLE, OutRLE, SizeOutRLE, InLZW
SECTION .text
ALIGN 32
[BITS 32]
;/////////////////////////////////////////////////
;GIF LZW /////////////////////////////////////////
ClrAb EQU 256
EndOF EQU 257
InLZW:
ARG InBuffLZW, 4, OutLZW, 4, LenOutLZW, 4
PUSH EDI
PUSH ESI
PUSH EBX
MOV EAX,[EBP+OutLZW]
MOV ECX,[EBP+LenOutLZW]
MOV EBX,[EBP+InBuffLZW]
MOV [OutBuffIndex],EAX
MOV [OutBuffSizeLZW],ECX
MOVD xmm4,EAX ; [OutBuffIndex]
MOV [BuffPtrLZW],EBX
XOR EAX,EAX
MOV EBP,ECX ; remaining bytes count
MOV DWORD [UtlBitCurAdd],EAX
MOV DWORD [NbBitCode],9
CALL GetLZWCode ; saute le premier clear code
.ClrAbLZW:
MOV DWORD [NbBitCode],9
MOV DWORD [FreeAb],258
MOV DWORD [MaxCode],511
CALL GetLZWCode
MOVD EDI,xmm4 ; [OutBuffIndex]
STOSB
DEC EBP ; bytes out count ++
MOV [Suffix_Code],EAX
MOV [CasSpecial],EAX
MOVD xmm4,EDI
.BcGtCodeLZW:
CALL GetLZWCode
CMP EAX,ClrAb
JE .ClrAbLZW
CMP EAX,EndOF
JE .FinInLZW
XCHG EAX,[Suffix_Code]
MOV [Prefix_Code],EAX
MOV [Old_Code],EAX
MOV EDX,[Suffix_Code]
MOV ECX,[FreeAb]
;**** DECODAGE ------ DEBUT
XOR EDI,EDI ; DStackPtr =0
CMP EDX,ECX
JB .PasCasSpecial
.CasSpecial:
MOV AL,[CasSpecial]
MOV EDX,[Old_Code]
MOV [_DStack+EDI],AL
INC EDI
.PasCasSpecial:
.BoucDecodLZW:
CMP EDX,ClrAb
JA .PasConcret
.Concret:
MOV [_DStack+EDI],EDX
MOV [CasSpecial],EDX
MOV [DStackPtr],EDI
JMP .FinDecodeLZW
.PasConcret:
MOV AL,[_Suffix+EDX]
MOV EDX,[_Prefix+EDX*4]
MOV [_DStack+EDI],AL
INC EDI
JMP .BoucDecodLZW
.FinDecodeLZW:
; vide la pile de decodage dans le buff out
MOV ESI,[DStackPtr]
MOVD EDI,xmm4
.BoucVidStack:
MOV AL,[_DStack+ESI]
DEC EBP
JS .EndLZWBuffFull
STOSB
DEC ESI
JNS .BoucVidStack
MOVD xmm4,EDI ; [OutBuffIndex]
;**** DECODAGE ------ FIN
MOV EAX,[FreeAb]
MOV ECX,[Prefix_Code]
MOV [_Prefix+EAX*4],ECX
MOV DL,[CasSpecial]
MOV [_Suffix+EAX],DL
MOV EAX,[FreeAb] ; si [FreeAb]+1>[MaxCode] ?
INC EAX
CMP EAX,[MaxCode]
MOV [FreeAb],EAX
JBE .BcGtCodeLZW; ; alors
CMP DWORD [NbBitCode],BYTE 12
JE .PasExtNbBit
MOV ECX,[NbBitCode]
INC ECX
MOV EDX,1
MOV [NbBitCode],ECX
SHL EDX,CL
DEC EDX
MOV [MaxCode],EDX ; fin si
.PasExtNbBit:
JMP .BcGtCodeLZW
.FinInLZW:
MOV EAX,[OutBuffSizeLZW]
SUB EAX,EBP
JMP SHORT .NormEnd
.EndLZWBuffFull:
MOV EAX,EBP
.NormEnd:
POP EBX
POP ESI
POP EDI
RETURN
GetLZWCode:
MOV ECX,[UtlBitCurAdd]
CMP ECX,BYTE 32
JE .SpecialLire
ADD ECX,[NbBitCode]
CMP ECX,BYTE 32
MOV EAX,[EBX]
MOV ECX,[UtlBitCurAdd]
JBE .LireNorm
MOV EDX,[EBX+4]
SHRD EAX,EDX,CL
ADD EBX,BYTE 4
SUB DWORD [UtlBitCurAdd],BYTE 32
JMP SHORT .FinLireLZW
.SpecialLire:
ADD EBX,BYTE 4
MOV EAX,[EBX]
MOV DWORD [UtlBitCurAdd],0
JMP SHORT .FinLireLZW
.LireNorm:
SHR EAX,CL
.FinLireLZW:
MOV ECX,[NbBitCode]
AND EAX,[MaxCode]
ADD DWORD [UtlBitCurAdd],ECX
RET
;///////////////////////////////////////////
; PCX RLE //////////////////////////////////
InRLE:
ARG InBuffRLE, 4, POutRLE, 4, LenOutRLE, 4
PUSH EDI
PUSH ESI
MOV EDX,[EBP+LenOutRLE]
MOV EDI,[EBP+POutRLE]
MOV ESI,[EBP+InBuffRLE]
ADD EDX,EDI
.BcInRLE:
LODSB
CMP AL,0xC0
JB .Isole
MOV CL,AL
AND CL,0x3f
LODSB
MOVZX ECX,CL
REP STOSB
JMP SHORT .PasIsoleRLE
.Isole:
STOSB
.PasIsoleRLE:
CMP EDI,EDX
JB .BcInRLE
POP ESI
POP EDI
RETURN
OutRLE:
ARG OutBuffRLE, 4, InRLE, 4, LenInRLE, 4, ResHzRLE, 4
PUSH EDI
PUSH ESI
PUSH EBX
MOV ESI,[EBP+InRLE]
MOV EDI,[EBP+OutBuffRLE]
MOV EDX,[EBP+LenInRLE]
.BcOutRLEResH:
MOV ECX,[EBP+ResHzRLE]
LODSB
DEC EDX
DEC ECX
MOV AH,AL
XOR BL,BL
.BcOutRLEGn:
LODSB
CMP BL,62
JAE .PrcOutRLE
CMP AL,AH
JNE .PrcOutRLE
INC BL
JMP SHORT .PrcBoucle
.PrcOutRLE:
MOV BH,AL
OR BL,BL
JNZ .PasIsole
MOV AL,AH
AND AL,0xC0
CMP AL,0xC0
JE .PasIsole
JMP SHORT .Isole
.PasIsole:
MOV AL,BL
INC AL
OR AL,0xC0
STOSB
.Isole: MOV AL,AH
STOSB
.AjNext:
MOV AH,BH
XOR BL,BL
JMP SHORT .PrcBoucle
.PrcBoucle:
DEC EDX
DEC ECX
JNZ .BcOutRLEGn
.LastByte:
OR BL,BL
JNZ .FPasIsole
MOV AL,AH
AND AL,0xC0
CMP AL,0xC0
JE .FPasIsole
JMP SHORT .FIsole
.FPasIsole:
MOV AL,BL
INC AL
OR AL,0xC0
STOSB
.FIsole:
MOV AL,AH
STOSB
OR EDX,EDX
JNZ .BcOutRLEResH
MOV EAX,EDI
.FinOutRLE:
POP EBX
POP ESI
POP EDI
RETURN
SizeOutRLE:
ARG SzInRLE, 4, SzLenInRLE, 4, SzResHzRLE, 4
PUSH EDI
PUSH ESI
PUSH EBX
MOV ESI,[EBP+SzInRLE]
XOR EDI,EDI
MOV EDX,[EBP+SzLenInRLE]
.BcOutRLEResH:
MOV ECX,[EBP+SzResHzRLE]
LODSB
DEC EDX
DEC ECX
MOV AH,AL
XOR BL,BL
.BcOutRLEGn:
LODSB
CMP BL,62
JAE .PrcOutRLE
CMP AL,AH
JNE .PrcOutRLE
INC BL
JMP SHORT .PrcBoucle
.PrcOutRLE:
MOV BH,AL
OR BL,BL
JNZ .PasIsole
MOV AL,AH
AND AL,0xC0
CMP AL,0xC0
JE .PasIsole
JMP SHORT .Isole
.PasIsole:
INC EDI
.Isole:
INC EDI
.AjNext:
MOV AH,BH
XOR BL,BL
JMP SHORT .PrcBoucle
.PrcBoucle:
DEC EDX
DEC ECX
JNZ .BcOutRLEGn
.LastByte:
OR BL,BL
JNZ .FPasIsole
MOV AL,AH
AND AL,0xC0
CMP AL,0xC0
JE .FPasIsole
JMP SHORT .FIsole
.FPasIsole:
INC EDI
.FIsole:
INC EDI
OR EDX,EDX
JNZ .BcOutRLEResH
MOV EAX,EDI
.FinOutRLE:
POP EBX
POP ESI
POP EDI
RETURN
SECTION .bss ALIGN=32
Prefix_Code RESD 1
Suffix_Code RESD 1
Old_Code RESD 1
CasSpecial RESD 1
DStackPtr RESD 1
NbBitCode RESD 1
MaxCode RESD 1
BuffPtrLZW RESD 1
BuffIndexLZW RESD 1
OutBuffLZW RESD 1
OutBuffSizeLZW RESD 1
OutBuffIndex RESD 1
FreeAb RESD 1
UtlBitCurAdd RESD 1
RestBytes RESD 1
CPTLZW RESD 1
CPTCLR RESD 1
_Prefix RESD 4096
_Suffix RESB 4096
_DStack RESB 4096