-
Notifications
You must be signed in to change notification settings - Fork 1
Expand file tree
/
Copy pathpts16.asm
More file actions
3209 lines (3007 loc) · 109 KB
/
pts16.asm
File metadata and controls
3209 lines (3007 loc) · 109 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
; Dust Ultimate Game Library (DUGL)
; Copyright (C) 2025 Fakhri Feki
;
; This program is free software: you can redistribute it and/or modify
; it under the terms of the GNU General Public License as published by
; the Free Software Foundation, either version 3 of the License, or
; (at your option) any later version.
; This program is distributed in the hope that it will be useful,
; but WITHOUT ANY WARRANTY; without even the implied warranty of
; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
; GNU General Public License for more details.
; You should have received a copy of the GNU General Public License
; along with this program. If not, see <https://www.gnu.org/licenses/>.
;
; contact: libdugl(at)hotmail.com
;=============================================================================
ALIGN 32
PutSurf16:
ARG SSN16, 4, XPSN16, 4, YPSN16, 4, PSType16, 4
PUSH ESI
PUSH EDI
PUSH EBX
MOV ESI,[EBP+SSN16]
MOV EDI,SrcSurf
CopySurfDA ; copy surf
MOV EAX,[EBP+XPSN16]
MOV EBX,[EBP+YPSN16]
MOV ESI,[EBP+PSType16]
MOV ECX,EAX
MOV EDX,EBX
; --- compute Put coordinates of the View inside the Surf
; EAX: MaxX, EBX; MaxY, ECX: MinX, EDX: MnY
TEST ESI,1
JZ .NormHzPut
SUB EAX,[SMinX]
SUB ECX,[SMaxX]
JMP SHORT .InvHzPut
.NormHzPut:
ADD EAX,[SMaxX] ; EAX = PutMaxX
ADD ECX,[SMinX] ; ECX = PutMinX
.InvHzPut:
TEST ESI,2
JZ .NormVtPut
SUB EBX,[SMinY]
SUB EDX,[SMaxY]
JMP SHORT .InvVtPut
.NormVtPut:
ADD EBX,[SMaxY] ; EBX = PutMaxY
ADD EDX,[SMinY] ; EDX = PutMinY
.InvVtPut:
; InView inside (MinX, MinY, MaxX, MaxY)
CMP EAX,[MinX]
JL .PasPutSurf
CMP EBX,[MinY]
JL .PasPutSurf
CMP ECX,[MaxX]
JG .PasPutSurf
CMP EDX,[MaxY]
JG .PasPutSurf
MOV [PType],ESI ; save
; compute the clipped/unclipped put rectangle coordinaates in (PutSurfMinX, PutSurfMinY, PutSurfMaxX, PutSurfMaxY)
;==========================================
; MOV EDI,[MaxX]
; MOV EBP,[MaxY]
; CMP EAX,EDI ; PMaxX <= MaxX ?
; JLE SHORT .NoPSMaxXClip
; MOV [PutSurfMaxX],EDI
; JMP SHORT .PSMaxXClip
;.NoPSMaxXClip:
; MOV [PutSurfMaxX],EAX
;.PSMaxXClip:
; CMP EBX,EBP ; PMaxY <= MaxY ?
; JLE SHORT .NoPSMaxYClip
; MOV [PutSurfMaxY],EBP
; JMP SHORT .PSMaxYClip
;.NoPSMaxYClip:
; MOV [PutSurfMaxY],EBX
;.PSMaxYClip:
; MOV EDI,[MinX]
; MOV EBP,[MinY]
; CMP ECX,EDI ; PMinX >= MinX
; JGE SHORT .NoPSMinXClip
; MOV [PutSurfMinX],EDI
; JMP SHORT .PSMinXClip
;.NoPSMinXClip:
; MOV [PutSurfMinX],ECX
;.PSMinXClip:
; CMP EDX,EBP ; PMinY >= MinY
; JGE SHORT .NoPSMinYClip
; MOV [PutSurfMinY],EBP
; JMP SHORT .PSMinYClip
;.NoPSMinYClip:
; MOV [PutSurfMinY],EDX
;.PSMinYClip:
;=========================
;MOV ESI,[EBP+PSType16] ; restore
CMP EAX,[MaxX]
CMOVG EAX,[MaxX]
CMP EBX,[MaxY]
MOV [PutSurfMaxX],EAX ;-
CMOVG EBX,[MaxY]
CMP ECX,[MinX]
MOV [PutSurfMaxY],EBX ;-
CMOVL ECX,[MinX]
CMP EDX,[MinY]
MOV [PutSurfMinX],ECX ;-
CMOVL EDX,[MinY]
MOV [PutSurfMinY],EDX ;-
; --- compute Put coordinates of the entire Surf (as if source surf is full view)
; EAX: MaxX, EBX; MaxY, ECX: MinX, EDX: MnY
MOV EAX,[EBP+XPSN16] ; EAX = PutMaxX / without clipping
MOV EBX,[EBP+YPSN16] ; EBX = PutMaxY / without clipping
MOV ECX,EAX ; ECX = PutMinX / without clipping
MOV EDX,EBX ; EDX = PutMinY / without clipping
TEST ESI,1
MOV EDI,[SOrgX]
JZ SHORT .FNormHzPut
SUB ECX,[SResH]
ADD EAX,EDI
LEA ECX,[ECX+EDI+1]
JMP SHORT .FInvHzPut
.FNormHzPut:
ADD EAX,[SResH]
SUB ECX,EDI ; MinX = ECX = posXPut - SOrgX
SUB EAX,EDI
DEC EAX ; MaxX = EAX = posXPut + (SResH -1) - SOrgX
.FInvHzPut:
TEST ESI,2
MOV EDI,[SOrgY]
JZ .FNormVtPut
SUB EDX,[SResV]
ADD EBX,EDI
LEA EDX,[EDX+EDI+1]
JMP SHORT .FInvVtPut
.FNormVtPut:
ADD EBX,[SResV]
SUB EDX,EDI ; MinX = ECX = posXPut - SOrgX
SUB EBX,EDI
DEC EBX ; MaxY = EBX = posYPut + (SResV -1) - SOrgY
.FInvVtPut:
;-----------------------------------------------
CMP EAX,[PutSurfMaxX]
JG .PutSurfClip
CMP EBX,[PutSurfMaxY]
JG .PutSurfClip
CMP ECX,[PutSurfMinX]
JL .PutSurfClip
CMP EDX,[PutSurfMinY]
JL .PutSurfClip
;JMP .PutSurfClip
; PutSurf non Clipper *****************************
MOV EBP,[SResV]
TEST ESI,2 ; vertically reversed ?
JZ .NormAdSPut
MOV ESI,[Srlfb]
MOV EAX,[SNegScanLine]
ADD ESI,[SSizeSurf] ; ESI start of the last line in the surf
ADD ESI,EAX
ADD EAX,EAX
JMP SHORT .InvAdSPut
.NormAdSPut:
XOR EAX,EAX
MOV ESI,[Srlfb] ; ESI : start copy adress
.InvAdSPut:
MOV EDI,EBX ; PutMaxY or the top left corner
IMUL EDI,[NegScanLine]
LEA EDI,[EDI+ECX*2] ; += PutMinX*2 top left croner
MOV EDX,[ScanLine]
ADD EDI,[vlfb]
SUB EDX,[SScanLine] ; EDX : dest adress plus
MOV [Plus2],EDX
TEST BYTE [PType],1
MOV EDX,[SResH]
JNZ .InvHzPSurf
MOV [Plus],EAX
.PutSurf:
XOR ECX,ECX
.BcPutSurf:
MOV EBX,EDX ; = [SResH] or clipped width
TEST EDI,2 ; dword aligned ?
JZ SHORT .FPasStBAv
DEC EBX
MOVSW
JZ SHORT .FinSHLine
.FPasStBAv:
TEST EDI,4 ; qword aligned ?
JZ SHORT .PasStDAv
CMP EBX,2
JL SHORT .StBAp
MOVSD
SUB EBX,BYTE 2
.PasStDAv:
;--
TEST EDI, 8
JZ SHORT .PasStQAv
CMP EBX,BYTE 4
JL SHORT .StDAp
MOVQ xmm0,[ESI]
SUB EBX,BYTE 4
MOVQ [EDI],xmm0
LEA ESI,[ESI+8]
LEA EDI,[EDI+8]
.PasStQAv:
SHLD ECX,EBX,29 ; ECX = EBX >> 3 ECX should be equal to zero
JECXZ .StQAp
.StoSSE: MOVDQU xmm0,[ESI]
DEC ECX
MOVDQA [EDI],xmm0
LEA ESI,[ESI+16]
LEA EDI,[EDI+16]
JNZ SHORT .StoSSE
AND EBX,BYTE 7
JZ SHORT .FinSHLine
.StQAp: TEST BL,4
JZ SHORT .StDAp
MOVQ xmm0,[ESI]
MOVQ [EDI], xmm0
LEA ESI,[ESI+8]
LEA EDI,[EDI+8]
;-----
.StDAp: TEST BL,BYTE 2
JZ SHORT .StBAp
MOVSD
.StBAp: TEST BL,1
JZ SHORT .PasStBAp
MOVSW
.PasStBAp:
.FinSHLine: ADD EDI,[Plus2]
ADD ESI,[Plus]
DEC EBP
JNZ .BcPutSurf
JMP .PasPutSurf
; Put surf unclipped reversed horizontally *************
.InvHzPSurf:
LEA EAX,[EAX+EDX*4] ; +=SScanLine*2
LEA ESI,[ESI+EDX*2] ; +=SScanLine
MOV [Plus],EAX
MOV EDX,[SResH]
.IPutSurf:
XOR ECX,ECX
.IBcPutSurf:
MOV EBX,EDX
.IBcStBAv:
TEST EDI,2
JZ SHORT .IFPasStBAv
SUB ESI, BYTE 2
MOV AX,[ESI]
DEC EBX
STOSW
JZ .IFinSHLine
.IFPasStBAv:
TEST EDI,4
JZ SHORT .IPasStDAv
CMP EBX,BYTE 1
JLE .IStBAp
SUB ESI,BYTE 4
MOV EAX,[ESI]
ROR EAX,16 ; reverse word order
STOSD
SUB EBX,BYTE 2
.IPasStDAv:
TEST EDI, 8
JZ SHORT .IPasStQAv
CMP EBX,BYTE 4
JL SHORT .IStDAp
SUB ESI,BYTE 8
MOVQ xmm0,[ESI]
PSHUFLW xmm0,xmm0,(0<<6) | (1<<4) | (2<<2) | (3) ; reverse order 11 10 01 00
SUB EBX,BYTE 4
MOVQ [EDI],xmm0
LEA EDI,[EDI+8]
.IPasStQAv:
SHLD ECX,EBX,29 ; ECX = EBX >> 3 ECX should be equal to zero
;MOV ECX,EBX
;SHR ECX,3
JECXZ .IStQAp
;ALIGN 4
.IStoSSE:
SUB ESI,BYTE 16
MOVQ xmm0,[ESI]
MOVQ xmm1,[ESI+8]
PSHUFLW xmm0,xmm0,(0<<6) | (1<<4) | (2<<2) | (3) ; reverse order 11 10 01 00
PSHUFLW xmm1,xmm1,(0<<6) | (1<<4) | (2<<2) | (3) ; reverse order 11 10 01 00
DEC ECX
PUNPCKLQDQ xmm1, xmm0
MOVDQA [EDI],xmm1
LEA EDI,[EDI+16]
JNZ SHORT .IStoSSE
AND BL,BYTE 7
JZ SHORT .IFinSHLine
.IStQAp:
TEST BL,4
JZ SHORT .IStDAp
SUB ESI,BYTE 8
MOVQ xmm0,[ESI]
PSHUFLW xmm0,xmm0,(0<<6) | (1<<4) | (2<<2) | (3) ; reverse order 11 10 01 00
MOVQ [EDI],xmm0
LEA EDI,[EDI+8]
.IStDAp:
TEST BL,2
JZ SHORT .IStBAp
SUB ESI,BYTE 4
MOV EAX,[ESI]
ROR EAX,16
STOSD
.IStBAp:
TEST BL,1
JZ SHORT .IPasStBAp
.IBcStBAp:
SUB ESI,BYTE 2
MOV AX,[ESI]
STOSW
.IPasStBAp:
.IFinSHLine:
ADD EDI,[Plus2]
ADD ESI,[Plus]
DEC EBP
JNZ .IBcPutSurf
JMP .PasPutSurf
.PutSurfClip:
; PutSurf Clipper **********************************************
XOR EDI,EDI ; Y Fin Source
XOR ESI,ESI ; X deb Source
MOV EBP,[PutSurfMinX]
CMP ECX,EBP ; CMP minx, MinX
JGE .PsInfMinX ; XP1<MinX
TEST BYTE [PType],1 ; INV HZ
JNZ .InvHzCalcDX
MOV ESI,EBP
SUB ESI,ECX ; ESI = MinX - XP2
MOV ECX,EBP
.InvHzCalcDX:
MOV ECX,EBP
.PsInfMinX:
MOV EBP,[PutSurfMaxY]
CMP EBX,EBP ; cmp maxy, MaxY
JLE .PsSupMaxY ; YP2>MaxY
MOV EDI,EBP
NEG EDI
;MOV [YP2],EBP
ADD EDI,EBX
MOV EBX,EBP
.PsSupMaxY:
MOV EBP,[PutSurfMinY]
CMP EDX,EBP ; YP1<MinY
JGE .PsInfMinY
MOV EDX,EBP
.PsInfMinY:
MOV EBP,[PutSurfMaxX]
CMP EAX,EBP ; XP2>MaxX
JLE .PsSupMaxX
TEST BYTE [PType],1
JZ .PsInvHzCalcDX
MOV ESI,EAX
SUB ESI,EBP ; ESI = XP2 - MaxX
.PsInvHzCalcDX:
MOV EAX,EBP
.PsSupMaxX:
SUB EAX,ECX ; XP2 - XP1
MOV EBP,[SScanLine]
LEA EAX,[EAX*2+2]
SUB EBP,EAX ; EBP = SResH-DeltaX, PlusSSurf
MOV [Plus],EBP
MOV EBP,EBX
SUB EBP,EDX ; YP2 - YP1
INC EBP ; EBP = DeltaY
MOV EDX,[ScanLine]
MOVD xmm0,EAX ; = DeltaX
SUB EDX,EAX ; EDX = ResH-DeltaX, PlusDSurfS
TEST BYTE [PType],2 ; inv VT ?
MOV [Plus2],EDX
JZ .CNormAdSPut
MOV EAX,[Srlfb] ; Si inverse vertical
ADD EAX,[SSizeSurf] ; go to the last buffer
SUB EAX,[SScanLine] ; jump to the first of the last line
LEA EAX,[EAX+ESI*2] ; +X1InSSurf*2 clipping
IMUL EDI,[SScanLine] ; Y1InSSurf*ScanLine
SUB EAX,EDI
MOV ESI,EAX
MOV EAX,[SScanLine]
ADD EAX,EAX
NEG EAX
JMP SHORT .CInvAdSPut
.CNormAdSPut:
IMUL EDI,[SScanLine]
XOR EAX,EAX
LEA EDI,[EDI+ESI*2]
ADD EDI,[Srlfb]
MOV ESI,EDI
.CInvAdSPut:
MOV EDI,EBX ; putSurf MaxY
IMUL EDI,[NegScanLine]
LEA EDI,[EDI+ECX*2] ; + XP1*2 as 16bpp
PSRLD xmm0,1 ; (deltaX*2) / 2
ADD EDI,[vlfb]
MOVD EDX,xmm0 ; DeltaX
TEST BYTE [PType],1
JNZ .CInvHzPSurf
ADD [Plus],EAX
JMP .PutSurf
.CInvHzPSurf: ; clipped and inversed horizontally
ADD EAX,[SScanLine]
LEA EAX,[EAX+EDX*2] ; add to jump to the end
LEA ESI,[ESI+EDX*2] ; jump to the end
MOV [Plus],EAX
JMP .IPutSurf
.PasPutSurf:
POP EBX
POP EDI
POP ESI
RETURN
; PUT masked Surf
;*****************
ALIGN 32
PutMaskSurf16:
ARG MSSN16, 4, MXPSN16, 4, MYPSN16, 4, MPSType16, 4
PUSH ESI
PUSH EDI
PUSH EBX
MOV ESI,[EBP+MSSN16]
MOV EDI,SrcSurf
CopySurfDA ; copy surf
MOV EAX,[EBP+MXPSN16]
MOV EBX,[EBP+MYPSN16]
MOV ESI,[EBP+MPSType16]
MOV ECX,EAX
MOV EDX,EBX
; --- compute Put coordinates of the View inside the Surf
; EAX: MaxX, EBX; MaxY, ECX: MinX, EDX: MnY
TEST ESI,1
JZ .NormHzPut
SUB EAX,[SMinX]
SUB ECX,[SMaxX]
JMP SHORT .InvHzPut
.NormHzPut:
ADD EAX,[SMaxX] ; EAX = PutMaxX
ADD ECX,[SMinX] ; ECX = PutMinX
.InvHzPut:
TEST ESI,2
JZ .NormVtPut
SUB EBX,[SMinY]
SUB EDX,[SMaxY]
JMP SHORT .InvVtPut
.NormVtPut:
ADD EBX,[SMaxY] ; EBX = PutMaxY
ADD EDX,[SMinY] ; EDX = PutMinY
.InvVtPut:
; InView inside (MinX, MinY, MaxX, MaxY)
CMP EAX,[MinX]
JL .PasPutSurf
CMP EBX,[MinY]
JL .PasPutSurf
CMP ECX,[MaxX]
JG .PasPutSurf
CMP EDX,[MaxY]
JG .PasPutSurf
CMP EAX,[MaxX]
PSHUFLW xmm0,[SMask],0
PUNPCKLQDQ xmm0,xmm0
CMOVG EAX,[MaxX]
CMP EBX,[MaxY]
MOVDQA [DQ16Mask],xmm0
MOV [PutSurfMaxX],EAX
CMOVG EBX,[MaxY]
CMP ECX,[MinX]
MOV [PutSurfMaxY],EBX
CMOVL ECX,[MinX]
CMP EDX,[MinY]
MOV [PutSurfMinX],ECX
CMOVL EDX,[MinY]
MOV [PutSurfMinY],EDX
; --- compute Put coordinates of the entire Surf
; EAX: MaxX, EBX; MaxY, ECX: MinX, EDX: MnY
MOV EAX,[EBP+MXPSN16]
MOV EBX,[EBP+MYPSN16]
MOV ECX,EAX
MOV EDX,EBX
TEST ESI,1
MOV EDI,[SOrgX]
JZ SHORT .FNormHzPut
SUB ECX,[SResH]
ADD EAX,EDI
LEA ECX,[ECX+EDI+1]
JMP SHORT .FInvHzPut
.FNormHzPut:
ADD EAX,[SResH]
SUB ECX,EDI ; MinX = ECX = posXPut - SOrgX
SUB EAX,EDI
DEC EAX ; MaxX = EAX = posXPut + (SResH -1) - SOrgX
.FInvHzPut:
TEST ESI,2
MOV EDI,[SOrgY]
JZ .FNormVtPut
SUB EDX,[SResV]
ADD EBX,EDI
LEA EDX,[EDX+EDI+1]
JMP SHORT .FInvVtPut
.FNormVtPut:
ADD EBX,[SResV]
SUB EDX,EDI ; MinX = ECX = posXPut - SOrgX
SUB EBX,EDI
DEC EBX ; MaxX = EAX = posXPut + (SResH -1) - SOrgX
.FInvVtPut:
;-----------------------------------------------
CMP EAX,[PutSurfMaxX]
JG .PutSurfClip
CMP EBX,[PutSurfMaxY]
JG .PutSurfClip
CMP ECX,[PutSurfMinX]
JL .PutSurfClip
CMP EDX,[PutSurfMinY]
JL .PutSurfClip
; PutSurf not Clipped *****************************
MOV [PType],ESI
MOV EBP,[SResV]
TEST ESI,2 ; vertically reversed ?
JZ .NormAdSPut
MOV ESI,[Srlfb]
MOV EAX,[SNegScanLine]
ADD ESI,[SSizeSurf] ; ESI start of the last line in the surf
ADD ESI,EAX
ADD EAX,EAX
JMP SHORT .InvAdSPut
.NormAdSPut:
XOR EAX,EAX
MOV ESI,[Srlfb] ; ESI : start copy adress
.InvAdSPut:
MOV EDI,EBX ; PutMaxY or the top left corner
IMUL EDI,[NegScanLine]
LEA EDI,[EDI+ECX*2] ; += PutMinX*2 top left croner
MOV EDX,[ScanLine]
ADD EDI,[vlfb]
SUB EDX,[SScanLine] ; EDX : dest adress plus
MOV [Plus2],EDX
TEST BYTE [PType],1
MOV EDX,[SResH]
JNZ .InvHzPSurf
MOV [Plus],EAX
.PutSurf:
XOR ECX,ECX
.BcPutSurf:
MOV EBX,EDX
.BcStBAv:
TEST EDI,6 ; dword aligned ?
JZ .FPasStBAv
MOV AX,[ESI]
CMP AX,[DQ16Mask]
LEA ESI,[ESI+2]
JZ .PasStBAv
STOSW
DEC EBX
JZ .FinSHLine
JMP .BcStBAv
.PasStBAv:
DEC EBX
LEA EDI,[EDI+2]
JZ .FinSHLine
JMP .BcStBAv
.FPasStBAv:
;--------
TEST EDI, 8
JZ .PasStQAv
CMP EBX,BYTE 4
JL .StBAp
MOVQ xmm2,[ESI]
MOVQ xmm1,xmm2
MOVQ xmm0,xmm2
MOVQ xmm4,[EDI]
PCMPEQW xmm2,[DQ16Mask]
PCMPEQW xmm1,[DQ16Mask]
PANDN xmm2,xmm0
PAND xmm4,xmm1
POR xmm2,xmm4
SUB EBX, BYTE 4
MOVQ [EDI],xmm2
LEA ESI,[ESI+8]
LEA EDI,[EDI+8]
.PasStQAv:
;-------
SHLD ECX,EBX,29
JZ .StBAp
;ALIGN 4
.StoSSE:
MOVDQU xmm2,[ESI]
MOVDQA xmm4,[EDI]
MOVDQA xmm1,xmm2
MOVDQA xmm0,xmm2
PCMPEQW xmm1,[DQ16Mask]
PCMPEQW xmm2,[DQ16Mask]
PAND xmm4,xmm1
PANDN xmm2,xmm0
POR xmm2,xmm4
DEC ECX
MOVDQA [EDI],xmm2
LEA ESI,[ESI+16]
LEA EDI,[EDI+16]
JNZ .StoSSE
.StBAp:
AND BL,BYTE 7
JZ .FinSHLine
.StQAp:
TEST BL,4
JZ .PasStQAp
MOVQ xmm2,[ESI]
MOVQ xmm1,xmm2
MOVQ xmm0,xmm2
MOVQ xmm4,[EDI]
PCMPEQW xmm2,[DQ16Mask]
PCMPEQW xmm1,[DQ16Mask]
PANDN xmm2,xmm0
PAND xmm4,xmm1
POR xmm2,xmm4
MOVQ [EDI],xmm2
LEA ESI,[ESI+8]
LEA EDI,[EDI+8]
.PasStQAp:
AND BL,BYTE 3
JZ SHORT .FinSHLine
.BcStBAp:
MOV AX,[ESI]
CMP AX,[DQ16Mask]
LEA ESI,[ESI+2]
JZ .BPasStBAp
DEC BL
STOSW
JNZ .BcStBAp
JMP SHORT .FinSHLine
.BPasStBAp:
DEC BL
LEA EDI,[EDI+2]
JNZ .BcStBAp
.PasStBAp:
.FinSHLine:
ADD EDI,[Plus2]
ADD ESI,[Plus]
DEC EBP
JNZ .BcPutSurf
JMP .PasPutSurf
; Put surf unclipped reversed horizontally *************
.InvHzPSurf:
LEA EAX,[EAX+EDX*4] ; +=SScanLine*2
LEA ESI,[ESI+EDX*2] ; +=SScanLine
MOV [Plus],EAX
MOV EDX,[SResH]
.IPutSurf:
XOR ECX,ECX
.IBcPutSurf:
MOV EBX,EDX
.IBcStBAv:
TEST EDI,6
JZ .IFPasStBAv
SUB ESI, BYTE 2
MOV AX,[ESI]
CMP AX,[DQ16Mask]
JZ .IBPasStBAv
DEC EBX
STOSW
JZ .IFinSHLine
JMP .IBcStBAv
.IBPasStBAv:
DEC EBX
LEA EDI,[EDI+2]
JZ .IFinSHLine
JMP .IBcStBAv
.IFPasStBAv:
TEST EDI, 8
JZ .IPasStQAv
CMP EBX,BYTE 4
JL .IPasStQAp
SUB ESI,BYTE 8
MOVQ xmm0,[ESI]
MOVQ xmm2,xmm0
MOVQ xmm1,xmm0
MOVQ xmm4,[EDI]
PSHUFLW xmm2,xmm2,(0<<6) | (1<<4) | (2<<2) | (3) ; reverse order 11 10 01 00
PSHUFLW xmm1,xmm1,(0<<6) | (1<<4) | (2<<2) | (3) ; reverse order 11 10 01 00
PSHUFLW xmm0,xmm0,(0<<6) | (1<<4) | (2<<2) | (3) ; reverse order 11 10 01 00
PCMPEQW xmm2,[DQ16Mask]
PCMPEQW xmm1,[DQ16Mask]
PANDN xmm2,xmm0
PAND xmm4,xmm1
POR xmm2,xmm4
SUB EBX,BYTE 4
MOVQ [EDI],xmm2
LEA EDI,[EDI+8]
.IPasStQAv:
SHLD ECX,EBX,29 ; ECX = EBX >> 3 : ECX should be zero
JZ .IStBAp
;ALIGN 4
.IStoSSE:
SUB ESI,BYTE 16
MOVDQA xmm3,[EDI]
MOVQ xmm2,[ESI] ; get again the reversed source
MOVQ xmm1,[ESI+8]
PSHUFLW xmm2,xmm2,(0<<6) | (1<<4) | (2<<2) | (3) ; reverse order 11 10 01 00
PSHUFLW xmm1,xmm1,(0<<6) | (1<<4) | (2<<2) | (3) ; reverse order 11 10 01 00
MOVDQA xmm4,[EDI]
PUNPCKLQDQ xmm1,xmm2
MOVDQA xmm0,xmm1
PCMPEQW xmm1,[DQ16Mask]
MOVDQA xmm2,xmm1
PAND xmm4,xmm1
PANDN xmm2,xmm0
POR xmm2,xmm4
DEC ECX
MOVDQA [EDI],xmm2
LEA EDI,[EDI+16]
JNZ .IStoSSE
.IStBAp:
AND BL,7
JZ .IFinSHLine
TEST BL,4
JZ .IPasStQAp
SUB ESI,BYTE 8
MOVQ xmm2,[ESI]
MOVQ xmm1,xmm2
MOVQ xmm0,xmm2
MOVQ xmm4,[EDI]
PSHUFLW xmm2,xmm2,(0<<6) | (1<<4) | (2<<2) | (3) ; reverse order 11 10 01 00
PSHUFLW xmm1,xmm1,(0<<6) | (1<<4) | (2<<2) | (3) ; reverse order 11 10 01 00
PSHUFLW xmm0,xmm0,(0<<6) | (1<<4) | (2<<2) | (3) ; reverse order 11 10 01 00
PCMPEQW xmm2,[DQ16Mask]
PCMPEQW xmm1,[DQ16Mask]
PANDN xmm2,xmm0
PAND xmm4,xmm1
POR xmm2,xmm4
MOVQ [EDI],xmm2
LEA EDI,[EDI+8]
.IPasStQAp:
AND BL,3
JZ .IFinSHLine
.IBcStBAp:
SUB ESI, BYTE 2
MOV AX,[ESI]
CMP AX,[DQ16Mask]
JZ .IBPasStBAp
DEC BL
STOSW
JNZ .IBcStBAp
JMP SHORT .IFinSHLine
.IBPasStBAp:
DEC BL
LEA EDI,[EDI+2]
JNZ .IBcStBAp
.IFinSHLine:
ADD EDI,[Plus2]
ADD ESI,[Plus]
DEC EBP
JNZ .IBcPutSurf
JMP .PasPutSurf
.PutSurfClip:
; PutSurf Clipper **********************************************
MOV [PType],ESI ; sauvegarde le type
XOR EDI,EDI ; Y Fin Source
XOR ESI,ESI ; X deb Source
MOV EBP,[PutSurfMinX]
CMP ECX,EBP ; CMP minx, MinX
JGE .PsInfMinX ; XP1<MinX
TEST BYTE [PType],1 ; INV HZ
JNZ .InvHzCalcDX
MOV ESI,EBP
;MOV [XP1],EBP ; XP1 = MinX
SUB ESI,ECX ; ESI = MinX - XP2
.InvHzCalcDX:
MOV ECX,EBP
.PsInfMinX:
MOV EBP,[PutSurfMaxY]
CMP EBX,EBP ; cmp maxy, MaxY
JLE .PsSupMaxY ; YP2>MaxY
MOV EDI,EBP
NEG EDI
;MOV [YP2],EBP
ADD EDI,EBX
MOV EBX,EBP
.PsSupMaxY:
MOV EBP,[PutSurfMinY]
CMP EDX,EBP ; YP1<MinY
JGE .PsInfMinY
MOV EDX,EBP
.PsInfMinY:
MOV EBP,[PutSurfMaxX]
CMP EAX,EBP ; XP2>MaxX
JLE .PsSupMaxX
TEST BYTE [PType],1
JZ .PsInvHzCalcDX
MOV ESI,EAX
SUB ESI,EBP ; ESI = XP2 - MaxX
.PsInvHzCalcDX:
MOV EAX,EBP
.PsSupMaxX:
SUB EAX,ECX ; XP2 - XP1
MOV EBP,[SScanLine]
LEA EAX,[EAX*2+2]
SUB EBP,EAX ; EBP = SResH-DeltaX, PlusSSurf
MOV [Plus],EBP
MOV EBP,EBX
SUB EBP,EDX ; YP2 - YP1
INC EBP ; EBP = DeltaY
MOV EDX,[ScanLine]
MOVD xmm0,EAX ; = DeltaX
SUB EDX,EAX ; EDX = ResH-DeltaX, PlusDSurfS
TEST BYTE [PType],2 ; inv VT ?
MOV [Plus2],EDX
JZ .CNormAdSPut
MOV EAX,[Srlfb] ; Si inverse vertical
ADD EAX,[SSizeSurf] ; go to the last buffer
SUB EAX,[SScanLine] ; jump to the first of the last line
LEA EAX,[EAX+ESI*2] ; +X1InSSurf*2 clipping
IMUL EDI,[SScanLine] ; Y1InSSurf*ScanLine
SUB EAX,EDI
MOV ESI,EAX
MOV EAX,[SScanLine]
ADD EAX,EAX
NEG EAX
JMP SHORT .CInvAdSPut
.CNormAdSPut:
IMUL EDI,[SScanLine]
XOR EAX,EAX
LEA EDI,[EDI+ESI*2]
ADD EDI,[Srlfb]
MOV ESI,EDI
.CInvAdSPut:
MOV EDI,EBX ; putSurf MaxY
IMUL EDI,[NegScanLine]
LEA EDI,[EDI+ECX*2] ; + XP1*2 as 16bpp
PSRLD xmm0,1 ; (deltaX*2) / 2
ADD EDI,[vlfb]
MOVD EDX,xmm0 ; DeltaX
TEST BYTE [PType],1
JNZ .CInvHzPSurf
ADD [Plus],EAX
JMP .PutSurf
.CInvHzPSurf: ; clipper et inverser horizontalement
ADD EAX,[SScanLine]
LEA EAX,[EAX+EDX*2] ; add to jump to the end
LEA ESI,[ESI+EDX*2] ; jump to the end
MOV [Plus],EAX
JMP .IPutSurf
.PasPutSurf:
POP EBX
POP EDI
POP ESI
RETURN
; -------------------------------
; Put a Surf blended with a color
; -------------------------------
ALIGN 32
PutSurfBlnd16:
ARG SSBN16, 4, XPSBN16, 4, YPSBN16, 4, PSBType16, 4, PSBCol16, 4
PUSH ESI
PUSH EDI
PUSH EBX
MOV ESI,[EBP+SSBN16]
MOV EDI,SrcSurf
CopySurfDA ; copy surf
; prepare col blending
MOV EAX,[EBP+PSBCol16] ;
MOV EBX,EAX ;
MOV ECX,EAX ;
MOV EDX,EAX ;
AND EBX,[QBlue16Mask] ; EBX = Bclr16 | Bclr16
SHR EAX,24
AND ECX,[QGreen16Mask] ; ECX = Gclr16 | Gclr16
AND AL,BlendMask ; remove any ineeded bits
AND EDX,[QRed16Mask] ; EDX = Rclr16 | Rclr16
XOR AL,BlendMask ; 31-blendsrc
MOV EDI,EAX
XOR AL,BlendMask ; 31-blendsrc
INC AL
SHR DX,5 ; right shift red 5bits
IMUL BX,AX
IMUL CX,AX
IMUL DX,AX
MOVD xmm3,EBX
MOVD xmm4,ECX
MOVD xmm5,EDX
MOVD xmm7,EDI
PSHUFLW xmm3,xmm3,0
PSHUFLW xmm4,xmm4,0
PSHUFLW xmm5,xmm5,0
PSHUFLW xmm7,xmm7,0
PUNPCKLQDQ xmm3,xmm3
PUNPCKLQDQ xmm4,xmm4
PUNPCKLQDQ xmm5,xmm5
PUNPCKLQDQ xmm7,xmm7
MOV EAX,[EBP+XPSBN16]
MOV EBX,[EBP+YPSBN16]
MOV ESI,[EBP+PSBType16]
MOV ECX,EAX
MOV EDX,EBX
; --- compute Put coordinates of the View inside the Surf
; EAX: MaxX, EBX; MaxY, ECX: MinX, EDX: MnY
TEST ESI,1
JZ .NormHzPut
SUB EAX,[SMinX]
SUB ECX,[SMaxX]
JMP SHORT .InvHzPut
.NormHzPut:
ADD EAX,[SMaxX] ; EAX = PutMaxX
ADD ECX,[SMinX] ; ECX = PutMinX
.InvHzPut:
TEST ESI,2
JZ .NormVtPut
SUB EBX,[SMinY]
SUB EDX,[SMaxY]
JMP SHORT .InvVtPut
.NormVtPut:
ADD EBX,[SMaxY] ; EBX = PutMaxY
ADD EDX,[SMinY] ; EDX = PutMinY
.InvVtPut:
; InView inside (MinX, MinY, MaxX, MaxY)
CMP EAX,[MinX]
JL .PasPutSurf
CMP EBX,[MinY]
JL .PasPutSurf
CMP ECX,[MaxX]
JG .PasPutSurf
CMP EDX,[MaxY]
JG .PasPutSurf
CMP EAX,[MaxX]
CMOVG EAX,[MaxX]
CMP EBX,[MaxY]
MOV [PutSurfMaxX],EAX ;-
CMOVG EBX,[MaxY]
CMP ECX,[MinX]
MOV [PutSurfMaxY],EBX ;-
CMOVL ECX,[MinX]
CMP EDX,[MinY]
MOV [PutSurfMinX],ECX ;-
CMOVL EDX,[MinY]