gradlew clean pub jreleaserFullRelease --dryrun

Execution failed for task ':jreleaserFullRelease'.
> maven.nexus2.maven-central.stagingRepository does not exist: target\staging-deploy

./build/staging-deploy
./picocli-codegen/build/staging-deploy
./picocli-groovy/build/staging-deploy
./picocli-shell-jline2/build/staging-deploy
./picocli-shell-jline3/build/staging-deploy
./picocli-spring-boot-starter/build/staging-deploy

plugins {
    id 'org.jreleaser' version '1.17.0'
}

apply plugin: 'java'
apply plugin: 'maven-publish'

task javadocJar(type: Jar, dependsOn: javadoc) {
    from javadoc.destinationDir
    archiveClassifier.set('javadoc')
}
task sourcesJar(type: Jar) {
    from sourceSets.main.java.srcDirs
    archiveClassifier.set('sources')
}
task testJar(type: Jar, dependsOn: compileTestJava) {
    from sourceSets.test.output
    archiveClassifier.set('tests')
}
task testSourcesJar(type: Jar) {
    from sourceSets.test.java.srcDirs
    archiveClassifier.set('test-sources')
}

artifacts {
    archives jar
    archives javadocJar
    archives sourcesJar
    archives testJar
    archives testSourcesJar
}
tasks.withType(GenerateModuleMetadata) {
    enabled = false // fix for https://github.com/remkop/picocli/issues/1152
}

// different for each module
group = PUBLISH_GROUP_ID
version = PUBLISH_VERSION

publishing {
    publications {
        release(MavenPublication) {
            from components.java
            artifact javadocJar
            artifact sourcesJar
            artifact testJar
            artifact testSourcesJar
            groupId = group
            artifactId = project.name
            version = PUBLISH_VERSION
            //version = "$projectVersion"
            // pom configuration for MavenPublication, as per https://docs.gradle.org/current/userguide/publishing_maven.html#sec:modifying_the_generated_pom
            pom {
                packaging = 'jar'
                name = project.name
                description = project.description
                url = 'https://picocli.info'
                inceptionYear = '2018'
                licenses {
                    license {
                        name = "The Apache Software License, version 2.0"
                        url = "http://www.apache.org/licenses/LICENSE-2.0.txt"
                        distribution = "repo"
                    }
                }
                developers {
                    developer {
                        id = "rpopma"
                        name = "Remko Popma"
                        email = "rpopma@apache.org"
                    }
                }
                scm {
                    url = "https://github.com/remkop/picocli/tree/master"
                    connection = 'scm:git:https://github.com/remkop/picocli.git'
                    developerConnection = 'scm:git:ssh://github.com:remkop/picocli.git'
                }
            }
        }
    }
    repositories {
        maven {
            url = layout.buildDirectory.dir('staging-deploy')
        }
    }
}

jreleaser {
    signing {
        active = 'RELEASE'
        armored = true
    }
    deploy {
        maven {
            nexus2 {
                'maven-central' {
                    active = 'RELEASE'
                    url = 'https://s01.oss.sonatype.org/service/local'
                    snapshotUrl = 'https://s01.oss.sonatype.org/content/repositories/snapshots/'
                    closeRepository = true
                    releaseRepository = false
                    stagingRepository('target/staging-deploy')
                }
            }
        }
    }
}