# Copyright 2026 Google LLC.

#

# Licensed under the Apache License, Version 2.0 (the "License");

# you may not use this file except in compliance with the License.

# You may obtain a copy of the License at

#

# http://www.apache.org/licenses/LICENSE-2.0

#

# Unless required by applicable law or agreed to in writing, software

# distributed under the License is distributed on an "AS IS" BASIS,

# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.

# See the License for the specific language governing permissions and

# limitations under the License.

# LiteRT-LM Orchestrator

cmake_minimum_required(VERSION 3.25 FATAL_ERROR)

project(LiteRT-LM-Orchestrator LANGUAGES NONE)

if(CMAKE_TOOLCHAIN_FILE)

set(_litertlm_cross_compile "ON")

else()

set(_litertlm_cross_compile "OFF")

endif()

set(LITERTLM_CROSSCOMPILING "${_litertlm_cross_compile}" CACHE INTERNAL "LiteRTLM cross compile flag")

set(LITERTLM_DOWNLOAD_DIR "${CMAKE_BINARY_DIR}/download" CACHE PATH "Directory for downloads")

set(LITERTLM_PYTHON_DOWNLOAD_DIR "${LITERTLM_DOWNLOAD_DIR}/python")

option(ENABLE_UV "Enables uv virtual environment for the build" OFF)

set(LITERTLM_ENV_WRAPPER "" CACHE INTERNAL

"LiteRT-LM: Environment variables for uv virtual environment")

set(LITERTLM_UV_ARGS "" CACHE INTERNAL

"LiteRT-LM: Arguments for uv virtual environment")

if(ENABLE_UV)

find_program(UV_EXECUTABLE uv REQUIRED)

set(LITERTLM_VENV_DIR "${CMAKE_BINARY_DIR}/.venv" CACHE PATH

"LiteRT-LM: Path to the uv virtual environment")

if(NOT EXISTS "${LITERTLM_VENV_DIR}")

message(STATUS "[LiteRTLM] --- Installing Python 3.13 ---")

message(STATUS "[LiteRTLM] Python download location: ${LITERTLM_PYTHON_DOWNLOAD_DIR}")

execute_process(

COMMAND ${UV_EXECUTABLE} python install 3.13 --managed-python --no-cache --force

--install-dir "${LITERTLM_PYTHON_DOWNLOAD_DIR}"

)

file(GLOB LITERTLM_PYTHON_DIR

"${LITERTLM_PYTHON_DOWNLOAD_DIR}/*cpython-3.13-*/"

)

message(STATUS "[LiteRTLM] LITERTLM_PYTHON_DIR: ${LITERTLM_PYTHON_DIR}")

set(LITERTLM_PYTHON_DIR ${LITERTLM_PYTHON_DIR} CACHE PATH "")

set(LITERTLM_PYTHON_INCLUDE_DIR ${LITERTLM_PYTHON_DIR}/include CACHE PATH "")

set(LITERTLM_PYTHON_BIN_DIR "${LITERTLM_PYTHON_DIR}/bin" CACHE PATH "")

set(LITERTLM_PYTHON_LIB_DIR "${LITERTLM_PYTHON_DIR}/lib" CACHE PATH "")

file(GLOB LITERTLM_PYTHON_EXE

"${LITERTLM_PYTHON_BIN_DIR}/python3${CMAKE_EXECUTABLE_SUFFIX}"

)

message(STATUS "[LiteRTLM] LITERTLM_PYTHON_EXE: ${LITERTLM_PYTHON_EXE}")

set(LITERTLM_PYTHON_EXE ${LITERTLM_PYTHON_EXE} CACHE PATH "")

message(STATUS "[LiteRTLM] --- Creating uv virtual environment ---")

message(STATUS "[LiteRTLM] Virtual environment path: ${LITERTLM_VENV_DIR}")

message(STATUS "[LiteRTLM] Python executable path: ${LITERTLM_PYTHON_EXE}")

execute_process(

COMMAND ${UV_EXECUTABLE}

venv "${LITERTLM_VENV_DIR}" --python "${LITERTLM_PYTHON_EXE}"

COMMAND_ERROR_IS_FATAL ANY

)

set(ENV{VIRTUAL_ENV} "${LITERTLM_VENV_DIR}")

set(Python3_FIND_VIRTUALENV FIRST)

include_directories(SYSTEM "${LITERTLM_PYTHON_INSTALL_DIR}/include")

endif()

message(STATUS "Using isolated Python: ${Python3_EXECUTABLE}")

set(LITERTLM_ENV_WRAPPER

"VIRTUAL_ENV=${LITERTLM_VENV_DIR}"

"PATH=${LITERTLM_VENV_DIR}/bin:$ENV{PATH}"

CACHE INTERNAL "LiteRT-LM: Environment variables for uv virtual environment"

)

set(LITERTLM_UV_ARGS

"-DPython3_ROOT_DIR=${LITERTLM_VENV_DIR}"

"-DPython3_FIND_VIRTUALENV=FIRST")

endif()

set(LITERTLM_BUILD_COMMAND_ARGS "--build" "<BINARY_DIR>")

# list(APPEND LITERTLM_BUILD_COMMAND_ARGS "--config" "$<CONFIG>")

set(LITERTLM_BUILD_COMMAND_ARGS "")

if(CMAKE_BUILD_PARALLEL_LEVEL)

list(APPEND LITERTLM_BUILD_COMMAND_ARGS "--parallel" "${CMAKE_BUILD_PARALLEL_LEVEL}")

endif()

if(CMAKE_VERBOSE_MAKEFILE)

list(APPEND LITERTLM_BUILD_COMMAND_ARGS "--verbose")

endif()

option(ENABLE_CCACHE "Enables the use of ccache" OFF)

if(${ENABLE_CCACHE} STREQUAL "ON")

find_program(CCACHE_PROGRAM ccache)

if(CCACHE_PROGRAM)

message(STATUS "Using CCache to speed up builds")

set(CMAKE_C_COMPILER_LAUNCHER "${CCACHE_PROGRAM}")

set(CMAKE_CXX_COMPILER_LAUNCHER "${CCACHE_PROGRAM}")

else()

message(WARNING "CCache not found. Install it (`sudo apt install ccache`) for faster builds!")

endif()

endif()

if(WIN32)

set(LITERTLM_BIN_EXT "exe")

set(LITERTLM_STATIC_LIB_EXT ".lib")

set(LITERTLM_DYN_LIB_EXT ".dll")

set(LITERTLM_LIB_PREFIX "")

elseif(APPLE)

set(LITERTLM_BIN_EXT "")

set(LITERTLM_STATIC_LIB_EXT ".a")

set(LITERTLM_DYN_LIB_EXT ".dylib")

set(LITERTLM_LIB_PREFIX "lib")

else()

set(LITERTLM_BIN_EXT "")

set(LITERTLM_STATIC_LIB_EXT ".a")

set(LITERTLM_DYN_LIB_EXT ".so")

set(LITERTLM_LIB_PREFIX "lib")

endif()

message(STATUS "[LiteRTLM] Setting Library extensions to: '${LITERTLM_STATIC_LIB_EXT}' and '${LITERTLM_DYN_LIB_EXT}'")

set(LITERTLM_PROJECT_ROOT "${CMAKE_CURRENT_SOURCE_DIR}" CACHE PATH "LiteRT-LM: Absolute path to the repository root")

set(LITERTLM_TOOLCHAIN_ARGS "" CACHE STRING "String used to define parameterized CMAKE_ARGS")

set(LITERTLM_PREBUILD_DIR "${CMAKE_CURRENT_BINARY_DIR}/prebuild")

set(LITERTLM_PREBUILD_BINARY_DIR "${LITERTLM_PREBUILD_DIR}/build")

set(LITERTLM_PREBUILD_STAMP_DIR "${LITERTLM_PREBUILD_DIR}/stamps")

set(LITERTLM_PREBUILD_TMP_DIR "${LITERTLM_PREBUILD_DIR}/tmp")

set(LITERTLM_PREBUILD_DOWNLOAD_DIR "${LITERTLM_PREBUILD_DIR}/download")

set(LITERTLM_PREBUILD_INSTALL_DIR "${LITERTLM_PREBUILD_DIR}/install")

set(LITERTLM_PREBUILD_EXTERNAL_PROJECT_DIR "${LITERTLM_PREBUILD_BINARY_DIR}/external")

set(LITERTLM_DIR "${CMAKE_CURRENT_BINARY_DIR}/litert_lm")

set(LITERTLM_BINARY_DIR "${LITERTLM_DIR}/build")

set(LITERTLM_STAMP_DIR "${LITERTLM_DIR}/stamps")

set(LITERTLM_TMP_DIR "${LITERTLM_DIR}/tmp")

set(LITERTLM_DOWNLOAD_DIR "${LITERTLM_DIR}/download")

set(LITERTLM_INSTALL_DIR "${LITERTLM_DIR}/install")

set(LITERTLM_PACKAGE_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/cmake/packages/litert_lm")

set(LITERTLM_PREBUILD_TARGETS "absl gtest protobuf flatbuffers")

set(LITERTLM_PREBUILD_EXE "protoc flatc")

if(DEFINED LITERTLM_CC AND DEFINED LITERTLM_CXX)

message(STATUS "[LiteRTLM] Prebuild: Using host compilers: CC=${LITERTLM_CC}, CXX=${LITERTLM_CXX}")

set(LITERTLM_HOST_CC_COMPILER ${LITERTLM_CC} CACHE PATH "LiteRT-LM: C compiler for prebuild phase")

set(LITERTLM_HOST_CXX_COMPILER ${LITERTLM_CXX} CACHE PATH "LiteRT-LM: C++ compiler for prebuild phase")

else()

message(STATUS "[LiteRTLM] Prebuild: Using default host compilers: CC=${CMAKE_C_COMPILER}, CXX=${CMAKE_CXX_COMPILER}")

set(LITERTLM_HOST_CC_COMPILER ${CMAKE_C_COMPILER} CACHE PATH "LiteRT-LM: C compiler for prebuild phase")

set(LITERTLM_HOST_CXX_COMPILER ${CMAKE_CXX_COMPILER} CACHE PATH "LiteRT-LM: C++ compiler for prebuild phase")

endif()

if(DEFINED LITERTLM_CC_NDK AND DEFINED LITERTLM_CXX_NDK)

message(STATUS "[LiteRTLM] Target: Using NDK compilers: CC_NDK=${LITERTLM_CC_NDK}, CXX_NDK=${LITERTLM_CXX_NDK}")

set(LITERTLM_TARGET_CC_COMPILER ${LITERTLM_CC_NDK} CACHE PATH "LiteRT-LM: C compiler for NDK phase")

set(LITERTLM_TARGET_CXX_COMPILER ${LITERTLM_CXX_NDK} CACHE PATH "LiteRT-LM: C++ compiler for NDK phase")

else()

message(STATUS "[LiteRTLM] Target: host compilers: CC=${LITERTLM_HOST_CC_COMPILER}, CXX=${LITERTLM_HOST_CXX_COMPILER}")

set(LITERTLM_TARGET_CC_COMPILER ${LITERTLM_HOST_CC_COMPILER} CACHE PATH "LiteRT-LM: C compiler for prebuild phase")

set(LITERTLM_TARGET_CXX_COMPILER ${LITERTLM_HOST_CXX_COMPILER} CACHE PATH "LiteRT-LM: C++ compiler for prebuild phase")

endif()

include(ExternalProject)

ExternalProject_Add(

prebuild

PREFIX "${LITERTLM_PREBUILD_DIR}"

SOURCE_DIR "${LITERTLM_PACKAGE_SOURCE_DIR}"

BINARY_DIR "${LITERTLM_PREBUILD_BINARY_DIR}"

STAMP_DIR "${LITERTLM_PREBUILD_STAMP_DIR}"

TMP_DIR "${LITERTLM_PREBUILD_TMP_DIR}"

DOWNLOAD_DIR "${LITERTLM_PREBUILD_DOWNLOAD_DIR}"

INSTALL_DIR "${LITERTLM_PREBUILD_INSTALL_DIR}"

LIST_SEPARATOR "|"

CONFIGURE_COMMAND

${CMAKE_COMMAND} -E env

CC=${LITERTLM_HOST_CC_COMPILER}

CXX=${LITERTLM_HOST_CXX_COMPILER}

${LITERTLM_ENV_WRAPPER}

${CMAKE_COMMAND} -S <SOURCE_DIR> -B <BINARY_DIR>

${LITERTLM_UV_ARGS}

"-DCMAKE_INSTALL_PREFIX=${LITERTLM_PREBUILD_INSTALL_DIR}"

"-DLITERTLM_ORCHESTRATION_PHASE=prebuild"

"-DLITERTLM_PREBUILD_PHASE=LITERT_PREBUILD_PHASE"

"-DLITERTLM_PROJECT_ROOT=${LITERTLM_PROJECT_ROOT}"

"-DLITERTLM_PREBUILD_TARGETS=${LITERTLM_PREBUILD_TARGETS}"

"-DLITERTLM_PREBUILD_EXTERNAL_PROJECT_DIR=${LITERTLM_PREBUILD_EXTERNAL_PROJECT_DIR}"

"-DLITERTLM_BUILD_FETCH_CONTENT=OFF"

"-DLITERTLM_BUILD_EXTERNAL_PROJECTS=OFF"

"-DLITERTLM_BUILD_TARGETS=OFF"

"-DLITERTLM_BIN_EXT=${LITERTLM_BIN_EXT}"

"-DLITERTLM_STATIC_LIB_EXT=${LITERTLM_STATIC_LIB_EXT}"

"-DLITERTLM_DYN_LIB_EXT=${LITERTLM_DYN_LIB_EXT}"

"-DLITERTLM_LIB_PREFIX=${LITERTLM_LIB_PREFIX}"

"-DLITERTLM_GENERATE_TARGET_MAP=ON"

"-DLITERTLM_UV_ARGS=${LITERTLM_UV_ARGS}"

"-DLITERTLM_ENV_WRAPPER=${LITERTLM_ENV_WRAPPER}"

"-DLITERTLM_BUILD_COMMAND_ARGS=${LITERTLM_BUILD_COMMAND_ARGS}"

"-DLITERTLM_VENV_DIR=${LITERTLM_VENV_DIR}"

BUILD_COMMAND

${CMAKE_COMMAND} -E env ${LITERTLM_ENV_WRAPPER}

${CMAKE_COMMAND} --build <BINARY_DIR> ${LITERTLM_BUILD_COMMAND_ARGS}

INSTALL_COMMAND ""

)

# --- Host Tool Setup ---

if(NOT DEFINED LITERTLM_HOST_PROTOC)

set(LITERTLM_HOST_PROTOC "${LITERTLM_PREBUILD_EXTERNAL_PROJECT_DIR}/protobuf/install/bin/protoc" CACHE PATH "")

set(LITERTLM_HOST_PROTOC_BIN_DIR "${LITERTLM_PREBUILD_EXTERNAL_PROJECT_DIR}/protobuf/install/bin" CACHE PATH "")

endif()

if(NOT DEFINED LITERTLM_HOST_FLATC)

set(LITERTLM_HOST_FLATC "${LITERTLM_PREBUILD_EXTERNAL_PROJECT_DIR}/flatbuffers/install/bin/flatc" CACHE PATH "")

set(LITERTLM_HOST_FLATC_BIN_DIR "${LITERTLM_PREBUILD_EXTERNAL_PROJECT_DIR}/flatbuffers/install/bin" CACHE PATH "")

endif()

if(DEFINED CMAKE_TOOLCHAIN_FILE)

set(LITERTLM_TOOLCHAIN_FILE "-DCMAKE_TOOLCHAIN_FILE=${CMAKE_TOOLCHAIN_FILE}" CACHE PATH "")

endif()

if(DEFINED LITERTLM_TOOLCHAIN_SCRIPT)

message(STATUS "[LiteRTLM] Executing toolchain script -> ${LITERTLM_TOOLCHAIN_SCRIPT}")

include("${LITERTLM_TOOLCHAIN_SCRIPT}")

endif()

set(LITERTLM_FBS_DIR "${LITERTLM_PROJECT_ROOT}/schema/core")

set(LITERTLM_FLATBUFFERS_FILES "litertlm_header_schema.fbs")

ExternalProject_Add(

litert_lm

DEPENDS prebuild

PREFIX "${LITERTLM_DIR}"

SOURCE_DIR "${LITERTLM_PACKAGE_SOURCE_DIR}"

BINARY_DIR "${LITERTLM_BINARY_DIR}"

STAMP_DIR "${LITERTLM_STAMP_DIR}"

TMP_DIR "${LITERTLM_TMP_DIR}"

DOWNLOAD_DIR "${LITERTLM_DOWNLOAD_DIR}"

INSTALL_DIR "${LITERTLM_INSTALL_DIR}"

LIST_SEPARATOR "|"

PATCH_COMMAND

${CMAKE_COMMAND} -E echo "[LiteRTLM] Generating FlatBuffers headers for LiteRT-LM..."

COMMAND ${LITERTLM_HOST_FLATC} --cpp

--gen-object-api --reflect-names

--gen-mutable -o "${LITERTLM_FBS_DIR}"

"${LITERTLM_FBS_DIR}/${LITERTLM_FLATBUFFERS_FILES}"

CONFIGURE_COMMAND

${CMAKE_COMMAND} -E env

CC=${LITERTLM_TARGET_CC_COMPILER}

CXX=${LITERTLM_TARGET_CXX_COMPILER}

${LITERTLM_ENV_WRAPPER}

${CMAKE_COMMAND} -S <SOURCE_DIR> -B <BINARY_DIR>

${LITERTLM_TOOLCHAIN_ARGS}

${LITERTLM_TOOLCHAIN_FILE}

${LITERTLM_UV_ARGS}

"-DCMAKE_INSTALL_PREFIX=${LITERTLM_INSTALL_DIR}"

"-DCMAKE_C_COMPILER=${LITERTLM_TARGET_CC_COMPILER}"

"-DCMAKE_CXX_COMPILER=${LITERTLM_TARGET_CXX_COMPILER}"

"-DLITERTLM_CCRS_CXXFLAGS_KEY=${LITERTLM_CCRS_CXXFLAGS_KEY}"

"-DLITERTLM_CCRS_CFLAGS_KEY=${LITERTLM_CCRS_CFLAGS_KEY}"

"-DLITERTLM_CCRS_CXXFLAGS_VAL=${LITERTLM_CCRS_CXXFLAGS_VAL}"

"-DLITERTLM_CCRS_CFLAGS_VAL=${LITERTLM_CCRS_CFLAGS_VAL}"

"-DLITERTLM_TARGET_CC_COMPILER=${LITERTLM_TARGET_CC_COMPILER}"

"-DLITERTLM_TARGET_CXX_COMPILER=${LITERTLM_TARGET_CXX_COMPILER}"

"-DLITERTLM_TOOLCHAIN_FILE=${LITERTLM_TOOLCHAIN_FILE}"

"-DLITERTLM_TOOLCHAIN_ARGS=${LITERTLM_TOOLCHAIN_ARGS}"

"-DLITERTLM_ORCHESTRATION_PHASE=litert_lm"

"-DLITERTLM_TARGET_PHASE=litert_lm"

"-DLITERTLM_PROJECT_ROOT=${LITERTLM_PROJECT_ROOT}"

"-DLITERTLM_HOST_PROTOC=${LITERTLM_HOST_PROTOC}"

"-DLITERTLM_HOST_PROTOC_BIN_DIR=${LITERTLM_HOST_PROTOC_BIN_DIR}"

"-DLITERTLM_HOST_FLATC=${LITERTLM_HOST_FLATC}"

"-DLITERTLM_HOST_FLATC_BIN_DIR=${LITERTLM_HOST_FLATC_BIN_DIR}"

"-DLITERTLM_PREBUILD_TARGETS=${LITERTLM_PREBUILD_TARGETS}"

"-DLITERTLM_PREBUILD_EXTERNAL_PROJECT_DIR=${LITERTLM_PREBUILD_EXTERNAL_PROJECT_DIR}"

"-DLITERTLM_BUILD_FETCH_CONTENT=ON"

"-DLITERTLM_BUILD_EXTERNAL_PROJECTS=ON"

"-DLITERTLM_BUILD_TARGETS=ON"

"-DLITERTLM_GENERATE_TARGET_MAP=ON"

"-DCMAKE_CXX_FLAGS=-w"

"-DLITERTLM_BIN_EXT=${LITERTLM_BIN_EXT}"

"-DLITERTLM_STATIC_LIB_EXT=${LITERTLM_STATIC_LIB_EXT}"

"-DLITERTLM_DYN_LIB_EXT=${LITERTLM_DYN_LIB_EXT}"

"-DLITERTLM_LIB_PREFIX=${LITERTLM_LIB_PREFIX}"

"-DLITERTLM_UV_ARGS=${LITERTLM_UV_ARGS}"

"-DLITERTLM_ENV_WRAPPER=${LITERTLM_ENV_WRAPPER}"

"-DLITERTLM_BUILD_COMMAND_ARGS=${LITERTLM_BUILD_COMMAND_ARGS}"

"-DLITERTLM_VENV_DIR=${LITERTLM_VENV_DIR}"

"-DLITERTLM_CROSSCOMPILING=${LITERTLM_CROSSCOMPILING}"

BUILD_COMMAND

${CMAKE_COMMAND} -E env ${LITERTLM_ENV_WRAPPER}

${CMAKE_COMMAND} --build <BINARY_DIR> ${LITERTLM_BUILD_COMMAND_ARGS}

INSTALL_COMMAND ""

BUILD_ALWAYS TRUE

)